44b0引导过程详解

最新推荐文章于 2011-10-27 18:41:04 发布

「已注销」

最新推荐文章于 2011-10-27 18:41:04 发布

阅读量628

点赞数

文章标签： image 编译器 import parameters 工作 vector

本文链接：https://blog.youkuaiyun.com/idoit0204/article/details/2699130

版权

（更多经典请到中国电子顶级开发网嵌入式开发论坛，让我们一起进步http://www.eetop.cn/bbs/?fromuid=38730）

; *******************************************************
; * NAME    : 44BINIT.S     *
; * Version : 10.JAn.2003    *
; * Description:     *
; * C start up codes    *
; * Configure memory, Initialize ISR ,stacks *
; * Initialize C-variables    *
; * Fill zeros into zero-initialized C-variables *
; *******************************************************
;   说明: 为了学习方便，参考多篇资料对44B0的引导代码重新编辑、注释
; *******************************************************
;输入文件和外部变量；
; *******************************************************
   GET ../inc/option.s
   GET ../inc/memcfg.s

;bootloader要将RW段复制到ram中并将ZI段清零编译器使用下列段来记录各段的起始和结束地址
; |Image$$RO$$Base| ; RO段起始地址
; |Image$$RO$$Limit| ; RO段结束地址加1
; |Image$$RW$$Base| ; RW段起始地址
; |Image$$RW$$Limit| ; RW段结束地址加1
; |Image$$ZI$$Base| ; ZI段起始地址
; |Image$$ZI$$Limit| ; ZI段结束地址加1

    IMPORT Main    ; The main entry of mon program
; *******************************************************
;定义引导过程中需要设置的控制寄存器，仅针对44B0，44B0寄存器在44B0.H里有定义，但此时无法调用，需要自己定义
; *******************************************************
;Interrupt Control
INTPND     EQU 0x01e00004
INTMOD     EQU 0x01e00008
INTMSK     EQU 0x01e0000c
I_ISPR     EQU 0x01e00020
I_CMST     EQU 0x01e0001c

;Watchdog timer
WTCON EQU 0x01d30000

;Clock Controller
PLLCON     EQU 0x01d80000
CLKCON     EQU 0x01d80004
LOCKTIME    EQU 0x01d8000c

;Memory Controller
REFRESH     EQU 0x01c80024
; *******************************************************
;定义系统常量，主要是ARM工作模式，应该是针对所有ARM7，为CPSR的[0，4]所决定，主要是为了便于操作
; *******************************************************
USERMODE EQU 0x10 ;0b10000用户模式
FIQMODE EQU 0x11 ;0b10001FIQ模式
IRQMODE EQU 0x12 ;0b10010IRQ模式
SVCMODE EQU 0x13 ;0b10011管理模式
ABORTMODE EQU 0x17 ;0b10111中止模式
UNDEFMODE EQU 0x1b ;0b11011未定义
MODEMASK EQU 0x1f ;0b11111系统模式
NOINT EQU 0x80 ; 原来设置为C0，即： NOINT EQU 0xc0 ;但考虑到一些安全因素，暂时设置为80，尽量保证初始化时在ARM状态并关闭中断。

; *******************************************************
;定义系统变量，arm处理器有两种工作状态 1.arm:32位这种工作状态下执行字对准的arm指令 2.Thumb:16位这种工作状态执行半字对准的Thumb指令
;因为处理器分为16位 32位两种工作状态程序的编译器也是分16位和32两种编译方式所以下面的程序用于根据处理器工作状态确定编译器编译方式
;code16伪指令指示汇编编译器后面的指令为16位的thumb指令
;code32伪指令指示汇编编译器后面的指令为32位的arm指令
;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe编译），应该是统一为32位，该部分代码实际无多大意义，无法实现预期目的，修改如下
;影响如何，需要进一步验证
; *******************************************************

    GBLL    THUMBCODE
   ; [ {CONFIG} = 16
;THUMBCODE SETL {TRUE}
;   CODE32
; |
;THUMBCODE SETL {FALSE}
;   ]

; [ THUMBCODE
; CODE32   ;for start-up code for Thumb mode
; ]
   CODE32    ;32位
; *******************************************************
;宏定义，负责向量中断函数的加载，与C语言中宏的定义和使用类似
;下面包含的HandlerXXX HANDLER HandleXXX将都被下面这段程序展开 ,
;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字空间都有一个标号，以Handle***命名。
;在向量中断模式下使用“加载程序”来执行中断服务程序。
;向量中断模式和非向量中断模式的概念
;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址
;函数中节省了中断处理时间提高了中断处理速度标例如 ADC中断的向量地址为0xC0,则在0xC0处放如下代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会
;自动跳转到HandlerADC函数中
;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt pending寄存器中对应标志位置位然后跳转到位于0x18处的统一中断
;函数中该函数通过读取interrupt pending寄存器中对应标志位来判断中断源并根据优先级关系再跳到对应中断源的处理代码中
; *******************************************************

     MACRO
$HandlerLabel HANDLER $HandleLabel

$HandlerLabel
    sub     sp,sp,#4     ;decrement sp(to store jump address)
    stmfd   sp!,{r0}     ;PUSH the work register to stack(lr does't push because it return to original address)
    ldr     r0,=$HandleLabel;load the address of HandleXXX to r0
    ldr     r0,[r0]     ;load the contents(service routine start address) of HandleXXX
    str     r0,[sp,#4]     ;store the contents(ISR) of HandleXXX to stack
    ldmfd   sp!,{r0,pc}     ;POP the work register and pc(jump to ISR)
    MEND





; *******************************************************
;程序启动代码,程序入口地址，不妨看作C语言中的 MAIN（）入口，上面的代码看作MAIN之前的外部变量引用，全局常量、变量和宏定义
; *******************************************************

AREA Init,CODE,READONLY

    ENTRY
    b ResetHandler ;0x0   复位，特权模式，优先级1
    b HandlerUndef ;0X4   未定义指令中断模式，异常模式    6
    b HandlerSWI    ;0X8   软件中断，特权模式，，6
    b HandlerPabort ;0X0C 指令预取指中止，中止模式，5
    b HandlerDabort ;0X10 数据访问中止，中止模式，2
    b .      ;    0X14，未使用，保留
    b HandlerIRQ     ;0X18，外部中断，4,总入口,不同的中断还有不同的分入口地址,采用矢量中断模式时,不同中断源的地址入口固定,这也为系统自动计算中断服务程序入口地址提供了条件
    b HandlerFIQ     ;0X1C，快速中断，3,总入口,不同的中断还有不同的分入口地址
;***IMPORTANT NOTE***
;如果使用向量中断处理模式，上面两行的代码应该用下面两行代码代替
; subs pc,lr,#4 ;0X18，外部中断，4
; subs pc,lr,#4 ;0X1C，快速中断，3
; 这是因为当采用矢量中断模式时,一旦一个或多个中断发生,44B0通过硬件逻辑首先确定应该响应的中断,并计算出该中断的中断服务程序地址,该地址通过
;参数lr传递到下一条将要执行的指令即:subs pc,lr,#4;该指令存储在外部/快速中断的中断响应地址(0X18/0X1C)上,所以可直接跳转到相应中断源头的服务程序上
;中断发生--->(硬件计算服务程序地址,程序不参与)--->跳转到0X18或0X1C--->跳转到相应服务程序
;注意;上面的LR肯定已经不是中断发生时的指令地址,而是系统根据中断源类型生成的地址,中断发生时的地址保存在哪里,哈哈，我也不清楚,再找找了

VECTOR_BRANCH
    ;0X20-0XC0,30个中断源的向量表
    ldr pc,=HandlerEINT0    ;mGA    H/W interrupt vector table
    ldr pc,=HandlerEINT1    ;
    ldr pc,=HandlerEINT2    ;
    ldr pc,=HandlerEINT3    ;
    ldr pc,=HandlerEINT4567 ;
    ldr pc,=HandlerTICK     ;mGA
    b .
    b .
    ldr pc,=HandlerZDMA0    ;mGB
    ldr pc,=HandlerZDMA1    ;
    ldr pc,=HandlerBDMA0    ;
    ldr pc,=HandlerBDMA1    ;
    ldr pc,=HandlerWDT     ;
    ldr pc,=HandlerUERR01   ;mGB
    b .
    b .
    ldr pc,=HandlerTIMER0   ;mGC
    ldr pc,=HandlerTIMER1   ;
    ldr pc,=HandlerTIMER2   ;
    ldr pc,=HandlerTIMER3   ;
    ldr pc,=HandlerTIMER4   ;
    ldr pc,=HandlerTIMER5   ;mGC
    b .
    b .
    ldr pc,=HandlerURXD0    ;mGD
    ldr pc,=HandlerURXD1    ;
    ldr pc,=HandlerIIC     ;
    ldr pc,=HandlerSIO     ;
    ldr pc,=HandlerUTXD0    ;
    ldr pc,=HandlerUTXD1    ;mGD
    b .
    b .
    ldr pc,=HandlerRTC     ;mGKA
    b .       ;
    b .       ;
    b .       ;
    b .       ;
    b .       ;mGKA
    b .
    b .
    ldr pc,=HandlerADC     ;mGKB    0XC0
    b .       ;
    b .       ;
    b .       ;
    b .       ;
    b .       ;mGKB
    b .
    b .
   ;0xe0=EnterPWDN
    ldr pc,=EnterPWDN
;下面是具体的中断处理函数跳转的宏，通过上面的$HandlerLabel的宏定义展开后跳转到对应的中断处理函数（对于向量中断）
    LTORG

HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort

HandlerADC HANDLER HandleADC
HandlerRTC HANDLER HandleRTC
HandlerUTXD1 HANDLER HandleUTXD1
HandlerUTXD0 HANDLER HandleUTXD0
HandlerSIO HANDLER HandleSIO
HandlerIIC HANDLER HandleIIC
HandlerURXD1 HANDLER HandleURXD1
HandlerURXD0 HANDLER HandleURXD0
HandlerTIMER5 HANDLER HandleTIMER5
HandlerTIMER4 HANDLER HandleTIMER4
HandlerTIMER3 HANDLER HandleTIMER3
HandlerTIMER2 HANDLER HandleTIMER2
HandlerTIMER1 HANDLER HandleTIMER1
HandlerTIMER0 HANDLER HandleTIMER0
HandlerUERR01 HANDLER HandleUERR01
HandlerWDT HANDLER HandleWDT
HandlerBDMA1 HANDLER HandleBDMA1
HandlerBDMA0 HANDLER HandleBDMA0
HandlerZDMA1 HANDLER HandleZDMA1
HandlerZDMA0 HANDLER HandleZDMA0
HandlerTICK HANDLER HandleTICK
HandlerEINT4567 HANDLER HandleEINT4567
HandlerEINT3 HANDLER HandleEINT3
HandlerEINT2 HANDLER HandleEINT2
HandlerEINT1 HANDLER HandleEINT1
HandlerEINT0 HANDLER HandleEINT0

;
;One of the following two routines can be used for non-vectored interrupt.
;这段是没有使用装断向量模式下如何装载中断子程序,因为44B0有30个中断源,所以需要程序处理以确定调用那个中断程序
;0,1是局部标号,％B是向后搜索局部标号, %F是向前搜索局部标号。都是伪操作
;I_ISPR寄存器各位表明发生了应该调用那个中断子程序。只能1位置位,其它位为0,比如说串口1发送中断发生,这时I_ISPR的
;值为0X04,ldr r9,=I_ISPR
;ldr r9,[r9] 两条指令后,r9的内容为0X4 ,
;movs r9,r9,lsr #1 r9内容右移一位
;bcs %F1 判断是否把置位是否转移到C位,
;add r8,r8,#4 如果没有的R8加4
;如果r9内容为0x04 需要右移3次 ,之后r8的内容为8 然后HandleADC的地址加上r8的值就是串口1发送中断的地址,这个地址的内容是中断子程序的地址

IsrIRQ ;using I_ISPR register.
sub sp,sp,#4 ;reserved for PC
stmfd sp!,{r8-r9}

;IMPORTANT CAUTION
;if I_ISPC isn't used properly, I_ISPR can be 0 in this routine.

    ldr     r9,=I_ISPR
    ldr     r9,[r9]
    mov     r8,#0x0
0
    movs    r9,r9,lsr #1
    bcs     %F1
    add     r8,r8,#4
    b     %B0

1
    ldr     r9,=HandleADC
    add     r9,r9,r8
    ldr     r9,[r9]
    str     r9,[sp,#8]
    ldmfd   sp!,{r8-r9,pc}
;****************************************************
;到此处为止,44B0的启动框架已经完毕,后面的代码均可以看做是中断服务程序,程序的嵌套调用或者子程序
;* START START *
;****************************************************

;***************复位中断程序的处理*************************************
;负责硬件的初始化,处理流程:关看门狗及所有中断--->设置时钟--->初始化内存
;--->初始化堆栈--->复制RW到DRAM中,初始化ZI为0--->初始化其他硬件--->初始化设置中断模式
;--->跳转到应用程序
;***************复位中断程序的处理*************************************
ResetHandler
    ldr     r0,=WTCON     ;watch dog disable
    ldr     r1,=0x0
    str     r1,[r0]

    ldr     r0,=INTMSK
    ldr     r1,=0x07ffffff ;all interrupt disable
    str     r1,[r0]

    ;****************************************************
    ;* Set clock control registers   *
    ;****************************************************
    ldr r0,=LOCKTIME
    ldr r1,=800     ; count = t_lock * Fin (t_lock=200us, Fin=4MHz) = 800
    str r1,[r0]

    [ PLLONSTART
ldr r0,=PLLCON   ;temporary setting of PLL
ldr r1,=((M_DIV<<12)+(P_DIV<<4)+S_DIV) ;Fin=10MHz,Fout=40MHz
str r1,[r0]
    ]

    ldr     r0,=CLKCON
    ldr     r1,=0x7ff8     ;All unit block CLK enable
    str     r1,[r0]

    ;****************************************************
    ;* Set memory control registers   *
    ;****************************************************
    ldr     r0,=SMRDATA
    ldmia   r0,{r1-r13}
    ldr     r0,=0x01c80000 ;BWSCON Address
    stmia   r0,{r1-r13}

    ;****************************************************
    ;* Initialize stacks    *
    ;****************************************************
    ldr     sp, =SVCStack ;Why
    bl     InitStacks

    ;****************************************************
    ;* Setup IRQ handler    *
    ;****************************************************
    ldr     r0,=HandleIRQ  ;This routine is needed
    ldr     r1,=IsrIRQ   ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
    str     r1,[r0]

    ;********************************************************
    ;* Copy and paste RW data/zero initialized data     *
    ;********************************************************
    LDR     r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
    LDR     r1, =|Image$$RW$$Base| ; and RAM copy
    LDR     r3, =|Image$$ZI$$Base|
;Zero init base => top of initialised data

    CMP     r0, r1     ; Check that they are different
    BEQ     %F1
0
    CMP     r1, r3     ; Copy init data
    LDRCC   r2, [r0], #4    ;--> LDRCC r2, [r0] + ADD r0, r0, #4
    STRCC   r2, [r1], #4    ;--> STRCC r2, [r1] + ADD r1, r1, #4
    BCC     %B0
1
    LDR     r1, =|Image$$ZI$$Limit| ; Top of zero init segment
    MOV     r2, #0
2
    CMP     r3, r1     ; Zero init
    STRCC   r2, [r3], #4
    BCC     %B2

    [ :LNOT:THUMBCODE
BL Main     ;Don't use main() because ......
B .
    ]

    [ THUMBCODE      ;for start-up code for Thumb mode
orr     lr,pc,#1
bx      lr
CODE16
bl      Main     ;Don't use main() because ......
b       .
CODE32
    ]

;****************************************************
;* The function for initializing stack *
;****************************************************
InitStacks
;Don't use DRAM,such as stmfd,ldmfd......
;SVCstack is initialized before
;Under toolkit ver 2.50, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'

    mrs     r0,cpsr
    bic     r0,r0,#MODEMASK
    orr     r1,r0,#UNDEFMODE|NOINT
    msr     cpsr_cxsf,r1  ;UndefMode
    ldr     sp,=UndefStack

    orr     r1,r0,#ABORTMODE|NOINT
    msr     cpsr_cxsf,r1      ;AbortMode
    ldr     sp,=AbortStack

    orr     r1,r0,#IRQMODE|NOINT
    msr     cpsr_cxsf,r1      ;IRQMode
    ldr     sp,=IRQStack

    orr     r1,r0,#FIQMODE|NOINT
    msr     cpsr_cxsf,r1      ;FIQMode
    ldr     sp,=FIQStack

    bic     r0,r0,#MODEMASK|NOINT
    orr     r1,r0,#SVCMODE
    msr     cpsr_cxsf,r1      ;SVCMode
    ldr     sp,=SVCStack

;USER mode is not initialized.
mov pc,lr ;The LR register may be not valid for the mode changes.

;****************************************************
;* The function for entering power down mode   *
;****************************************************
;void EnterPWDN(int CLKCON);
EnterPWDN
    mov     r2,r0               ;r0=CLKCON
    ldr     r0,=REFRESH
    ldr     r3,[r0]
    mov     r1, r3
    orr     r1, r1, #0x400000   ;self-refresh enable
    str     r1, [r0]

    nop     ;Wait until self-refresh is issued. May not be needed.
    nop     ;If the other bus master holds the bus, ...
    nop     ; mov r0, r0
    nop
    nop
    nop
    nop

;enter POWERDN mode
ldr r0,=CLKCON
str r2,[r0]

;wait until enter SL_IDLE,STOP mode and until wake-up
    mov     r0,#0xff
0   subs    r0,r0,#1
    bne     %B0

;exit from DRAM/SDRAM self refresh mode.
    ldr     r0,=REFRESH
    str     r3,[r0]

    mov     pc,lr

LTORG

SMRDATA DATA
;*****************************************************************
;* Memory configuration has to be optimized for best performance *
;* The following parameter is not optimized. *
;*****************************************************************

;*** memory access cycle parameter strategy ***
; 1) Even FP-DRAM, EDO setting has more late fetch point by half-clock
; 2) The memory settings,here, are made the safe parameters even at 66Mhz.
; 3) FP-DRAM Parameters:tRCD=3 for tRAC, tcas=2 for pad delay, tcp=2 for bus load.
; 4) DRAM refresh rate is for 40Mhz.

DCD 0x11110090 ;Bank0=OM[1:0], Bank1~Bank7=16bit, bank2=8bit;
  DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0
DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1
DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2
DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3
DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4
DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5
DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT) ;REFRESH RFEN=1, TREFMD=0, trp=3clk, trc=5clk, tchr=3clk,count=1019
DCD 0x16    ;SCLK power mode, BANKSIZE 32M/32M
DCD 0x20   ;MRSR6 CL=2clk
DCD 0x20   ;MRSR7

ALIGN

;;;;数据段定义
AREA RamData, DATA, READWRITE

^ (_ISR_STARTADDRESS-0x500)

UserStack # 256 ;c1(c7)ffa00
SVCStack # 256 ;c1(c7)ffb00
UndefStack # 256 ;c1(c7)ffc00
AbortStack # 256 ;c1(c7)ffd00
IRQStack # 256 ;c1(c7)ffe00
FIQStack # 0 ;c1(c7)fff00

^ _ISR_STARTADDRESS
HandleReset # 4
HandleUndef # 4
HandleSWI # 4
HandlePabort # 4
HandleDabort # 4
HandleReserved # 4
HandleIRQ # 4
HandleFIQ # 4

;Don't use the label 'IntVectorTable',
;because armasm.exe cann't recognize this label correctly.
;the value is different with an address you think it may be.
;IntVectorTable
HandleADC # 4
HandleRTC # 4
HandleUTXD1 # 4
HandleUTXD0 # 4
HandleSIO # 4
HandleIIC # 4
HandleURXD1 # 4
HandleURXD0 # 4
HandleTIMER5 # 4
HandleTIMER4 # 4
HandleTIMER3 # 4
HandleTIMER2 # 4
HandleTIMER1 # 4
HandleTIMER0 # 4
HandleUERR01 # 4
HandleWDT # 4
HandleBDMA1 # 4
HandleBDMA0 # 4
HandleZDMA1 # 4
HandleZDMA0 # 4
HandleTICK # 4
HandleEINT4567 # 4
HandleEINT3 # 4
HandleEINT2 # 4
HandleEINT1 # 4
HandleEINT0 # 4 ;0xc1(c7)fff84

END