tcl语法和后端脚本实践 - 3：过程（proc）和过程定义（define_proc_attributes）

在EDA工具里边使用函数是非常方便的一个操作方式，高效、可控、并且不留”残渣“。这里，大家一起来看一下TCL里的过程（proc）的使用方法。

TCL里的过程，等效于C语言里的函数（function）
一个标准的proc一般具有如下的特点

proc proc_name {argument} {
	......
	return return_value
}

在使用的时候，直接输入过程名即可执行。
先来看一个下面的例子，

这是一个标准的过程，get_area就是这个过程名，直接执行它就可以了，这个过程名的作用就是得到整个设计里边的cell 的面积，源码示例如下

proc get_area {} {
  set area 0
  foreach_in_collection c [get_flat_cell *] {
    set area [expr [get_attribute $c area] + $area]
  }
  puts "cell area is: $area"
  return $area
}
define_proc_attributes get_area  \
  -info "get_area"

可以看到，除过计算面积意外，这里还有一个return和define_proc_attributes ，通过下面的操作来感受一下它们的意义

这个操作，就是使用 [] 来获取命令的返回值，这个是和shell里边的 `` 功能是一样的。

再来看看以下define_proc_attributes，这个命令可以定义你的proc的释义等。使用help proc_name来唤出来proc的解释

这个get_area仅仅就是计算所有cell面积的一个过程，如果只想计算某种特殊名称的cell 面积呢？没问题，使用argument轻松完成。
先看一下命令使用上的变化

可以看到，这里使用了pattern 这个参数，但是带来的便利性是巨大的，用户可以自行筛选结果，而不用去修改下边的proc本身。代码示例如下：

proc get_area {args} {
  parse_proc_arguments -args $args opt
  set pattern ""
  if {[info exists opt(-pattern) ]} {
    set pattern $opt(-pattern)
  } 
  set area 0
  foreach_in_collection c [get_flat_cell *${pattern}*] {
    set area [expr [get_attribute $c area] + $area]
  }
  puts "Pattarn \"${pattern}\" cell area is: $area"
  return $area
}
define_proc_attributes get_area  \
  -info "get_area for specified pattern" \
  -define_args {
    {-pattern   "instance name pattern"  AString string required } \
  }

可以看到，在proc get_area 里边，加入了如下的扩充

  parse_proc_arguments -args $args opt

这个即使参数解析的命令，通过这个命令，可以很方便的将外界的参数，转化为proc内部的数组（array）opt 用户通过调用这个数组，来实现参数的传递

此外，在定义过程属性的命令里边，也多了一些信息

  -define_args {
    {-pattern   "instance name pattern"  AString string required } \
  }

这个命令就是在定义argument的具体需求，具体格式释义如下面表格

arg_name option_help value_help data_type attributes

缩略语	描述	示例
arg_name	选项的名称	-pattern
option_help	选项的描述	“instance name pattern”
value_help	选项值的描述	AString
string	选项值的类别	string
attribute	选项的属性	required

这里的选项值的类别和选项的属性 都是需要符合工具的定义，必须要按照工具定义的来，类别一般分为：string/int/ boolean等，属性一般有：required/required等等。如果用户的输入和定义的不匹配，工具会报错。
更进一步，再来一个使用ref_name进行二次过滤，运行结果如下

proc的代码如下

proc get_area {args} {
  parse_proc_arguments -args $args opt
  set pattern ""
  if {[info exists opt(-pattern) ]} {
    set pattern $opt(-pattern)
  } 
  set area 0
  if {[info exists opt(-ref) ]} {
    foreach_in_collection c [get_flat_cell *${pattern}* -f "ref_name=~*$opt(-ref)*"] {
      set area [expr [get_attribute $c area] + $area]
    }
    puts "Pattarn \"${pattern}\" with ref \"$opt(-ref)\" cell area is: $area"
  } else {
    foreach_in_collection c [get_flat_cell *${pattern}*] {
      set area [expr [get_attribute $c area] + $area]
    }
    puts "Pattarn \"${pattern}\" cell area is: $area"
  }
  return $area
}

细心的同学们可能已经注意到了，这里使用了-ref这个新的argument，但是依然支持不带-ref的命令行操作
这是因为下面的代码的操作：

define_proc_attributes get_area  \
  -info "get_area for specified pattern" \
  -define_args {
    {-pattern   "instance name pattern"  AString string required } \
    {-ref       "ref name pattern"       AString string optional } \
  }

这里的**-ref …optional**就是这个作用，可以使用，也可以不使用，非必须的argument。
在文章的最开始提到proc还有一个不留“残渣”的作用，说的是proc里边的变量都是局部变量，每次执行的时候才会用到，但是不会影响当前的会话，利用这个特点可以放心的执行，又不用担心环境被破坏。用户只需要使用当前proc的返回值就可以了。

foreach t { place CTS route_opt } { 
  puts "area for $t is [get_area -pattern $t]"
} 

执行结果如下，可以看到，每次的返回值都回基于输入而产生不同，相互之间不影响

从上边的例子中，同学们已经能感知到proc的强大威力了吧！在真正的工作中，可以使用这些特点，构建自己的强大proc，从而可以更为方便的运行命令。
扫描二维码，关注公众号，获取更多技术文章。