OpenGL：几何着色器

几何着色器是一个可选的着色器，输入的的是一个图元（点、线或三角形）的一组顶点，我们可以：

• 输出相同的图元保持不变；
• 输出修改了顶点位置的相同类型图元；
• 输出不同类型的图元；
• 输出更多的其他图元；
• 删除图元。

在使用几何着色器的时候，我们首先要声明从顶点着色器输入的图元类型。

layout (type) in;

接受的 type 的值：

• points：绘制GL_POINTS图元时（1）。
• lines：绘制GL_LINES或GL_LINE_STRIP时（2）
• lines_adjacency：GL_LINES_ADJACENCY或GL_LINE_STRIP_ADJACENCY（4）
• triangles：GL_TRIANGLES、GL_TRIANGLE_STRIP或GL_TRIANGLE_FAN（3）
• triangles_adjacency：GL_TRIANGLES_ADJACENCY或GL_TRIANGLE_STRIP_ADJACENCY（6）

括号内的数字表示的是一个图元所包含的最小顶点数。

接下来，指定几何着色输出的图元类型：

layout (type) out;

这里的 type 接受的值：

• points
• line_strip
• triangle_strip

同时，我们可以设置它能够输出的顶点数量：

layout (type, max_vertices=N) out;

在操作了一个顶点之后我们需要调用 EmitVertex() 将新向量添加到图元中。在所有的向量都添加完之后，我们需要调用 EndPrimitive() 函数，将所有顶点合并为指定的输出渲染图元。多次调用 EndPrimitive() 能够生成多个图元。

以可视化法线为例：

1. 将法线变换到观察空间坐标系之前，先使用法线矩阵变换一次（几何着色器接受的位置向量是观察空间坐标，所以我们应该将法向量变换到相同的空间中）。

#version 440
layout(location = 0) in vec3 aPosition;
layout(location = 2) in vec3 aNormal;

out VS_OUT{
    vec3 normal;
} vs_out;

uniform mat4 view;
uniform mat4 model;

void main()
{
    gl_Position = view * model * vec4(aPosition, 1.0f);
    mat3 normalMatrix = mat3(transpose(inverse(view * model)));
    vs_out.normal = normalize(vec3(vec4(normalMatrix * aNormal, 0.0f)));
}

2. 变换后的观察空间法向量传递到几何着色器，我们在每个位置绘制一个法线向量：

#version 440
layout (triangles) in;
layout (line_strip, max_vertices = 6) out;

in VS_OUT{
    vec3 normal;
} gs_in[];

const float MAGNITUDE = 0.4;

uniform mat4 projection;

void GenerateLine(int index) {
    gl_Position = projection * gl_in[index].gl_Position;
    EmitVertex();
    gl_Position = projection * (gl_in[index].gl_Position + vec4(gs_in[index].normal, 0.0f) * MAGNITUDE);
    EmitVertex();
    EndPrimitive();
}

void main()
{
    GenerateLine(0);
    GenerateLine(1);
    GenerateLine(2);
}

3. 在片段着色器，将法线显示出来，给它上色。

#version 440
out vec4 fragColor;

void main()
{
    fragColor = vec4(1.0f, 0.0f, 0.0f, 1.0f);
}

4. 绘制出法线。绘制的顺序：

renderScene(mainShader); // 绘制主场景
renderScene(vNormalShader);  // 可视化法线