汇编语言 实验12 编写0号中断处理程序

1.asm

assume cs:codesg

codesg segment
start:
	   ;安装中断处理程序内容
	   mov ax,0
	   mov es,ax
	   mov di,200h
	   mov ax,cs
	   mov ds,ax
	   mov si,offset errorinfo
	   mov cx,offset errorinfo_all_end-offset errorinfo
	   cld
	   rep movsb
       ;设置中断向量表
	   mov ax,0
	   mov es,ax
	   mov es:[0],0200h
	   mov word ptr es:[2],0
	   mov ax,4c00h
	   int 21h
	   ;中断处理程序
errorinfo:
       mov ax,0b800h
	   mov es,ax
	   mov di,12*160+36*2
	   mov ax,0
	   mov ds,ax
	   mov si,200h+offset errorinfo_prog_end-offset errorinfo
	   mov cx,13
	s: mov al,ds:[si]
	   mov es:[di],al
	   inc di
	   inc di
	   inc si
	   loop s
	   mov ax,4c00h
	   int 21h
errorinfo_prog_end:
	   db "divide error!"
errorinfo_all_end:
       nop 
codesg ends
end start

2.asm（试验程序）

assume cs:codesg

codesg segment
start:
      mov ax,1000h
      mov bl,1
      div bl
      mov ax,4c00h
      int 21h
codesg ends
end start

编译后先执行1.exe，再执行2.exe
需要说明的是，Dosbox里没有写0号中断处理程序，如果打开初始向量表到所在的地址用-u查看是一些无意义的代码，如果直接执行除法溢出程序会陷入死循环。执行1.exe后，向量表和中断处理程序重置，再运行程序就能看到中断结果了。