学习Gremlin - 3.边的遍历操作

3.边的遍历操作

3.1、边遍历概念

边遍历是指通过顶点来访问与其有关联边的邻接顶点（或者仅访问邻接边），边遍历是图数据库与图计算的核心。

3.1.1、顶点为基准

• out(label): 根据指定的EdgeLabel来访问顶点的OUT方向邻接点（可以是零个EdgeLabel，代表所有类型边；也可以一个或多个EdgeLabel，代表任意给定EdgeLabel的边，下同）
• in(label): 根据指定的EdgeLabel来访问顶点的IN方向邻接点
• both(label): 根据指定的EdgeLabel来访问顶点的双向邻接点
• outE(label): 根据指定的EdgeLabel来访问顶点的OUT方向邻接边
• inE(label): 根据指定的EdgeLabel来访问顶点的IN方向邻接边
• bothE(label): 根据指定的EdgeLabel来访问顶点的双向邻接边

3.1.2、边为基准

• outV(): 访问边的出顶点（注意：这里是以边为基准，上述Step均以顶点为基准），出顶点是指边的起始顶点
• inV(): 访问边的入顶点，入顶点是指边的目标顶点，也就是箭头指向的顶点
• bothV(): 访问边的双向顶点
• otherV(): 访问边的伙伴顶点，即相对于基准顶点而言的另一端的顶点

3.2、实例讲解

• out()：访问顶点的OUT方向邻接点

// 先查询图中所有的顶点
// 然后访问顶点的OUT方向邻接点
// 注意：out()的基准必须是顶点
g.V().out()

// 访问某个顶点的OUT方向邻接点
// 注意'3:TinkerPop'是顶点的id
// 该id是插入顶点时自动生成的
g.V('3:TinkerPop').out()

目前讲解过的Gremlin Steps中，顶点的id可通过g.V()来获取，也可通过即将讲解的has()来获取（根据属性查询顶点）。

// 访问某个顶点的OUT方向邻接点
// 且限制仅“define”类型的边相连的顶点
g.V('3:TinkerPop').out('define')

• in()：访问顶点的IN方向邻接点

// 访问某个顶点的IN方向邻接点
g.V('3:TinkerPop').in()

// 访问某个顶点的IN方向邻接点
// 且限制了关联边的类型
g.V('3:TinkerPop').in('implements')

• both()：访问顶点的双向邻接点

// 访问某个顶点的双向邻接点
g.V('3:TinkerPop').both()

// 访问某个顶点的双向邻接点
// 且限制了关联边的类型
g.V('3:TinkerPop').both('implements', 'define')

• outE(): 访问顶点的OUT方向邻接边

// 访问某个顶点的OUT方向邻接边
g.V('3:TinkerPop').outE()

// 访问某个顶点的OUT方向邻接边
// 且限制了关联边的类型
g.V('3:TinkerPop').outE('define')

• inE(): 访问顶点的IN方向邻接边

// 访问某个顶点的IN方向邻接边
g.V('3:TinkerPop').inE()

// 访问某个顶点的IN方向邻接边
// 且限制了关联边的类型
g.V('3:TinkerPop').inE('implements')

• bothE(): 访问顶点的双向邻接边

// 访问某个顶点的双向邻接边
g.V('3:TinkerPop').bothE()

// 访问某个顶点的双向邻接边
// 且限制了关联边的类型
g.V('3:TinkerPop').bothE('define', 'implements')

• outV(): 访问边的出顶点

// 访问某个顶点的IN邻接边
// 然后获取边的出顶点
g.V('3:TinkerPop').inE().outV()

一般情况下，inE().outV()等价于in()

• inV(): 访问边的入顶点

// 访问某个顶点的OUT邻接边
// 然后获取边的入顶点
g.V('3:TinkerPop').outE().inV()

一般情况下，outE().inV()等价于out()

• bothV(): 访问边的双向顶点

// 访问某个顶点的OUT邻接边
// 然后获取边的双向顶点
g.V('3:TinkerPop').outE().bothV()

注意：bothV()会把源顶点也一起返回，因此只要源顶点有多少条出边，结果集中就会出现多少次源顶点

• otherV() : 访问边的伙伴顶点

// 访问某个顶点的OUT邻接边
// 然后获取边的伙伴顶点
g.V('3:TinkerPop').outE().otherV()

一般情况下，outE().otherV()等价于out()，inE().otherV()等价于in()

// 访问某个顶点的双向邻接边
// 然后获取边的伙伴顶点
g.V('3:TinkerPop').bothE().otherV()

一般情况下，bothE().otherV()等价于both()

3.3、综合运用

• 多度查询

// 4度out()查询
// 通过id找到“javeme”作者顶点
// 通过out()访问其创建的软件
// 继续通过out()访问软件实现的框架
// 继续通过out()访问框架包含的软件
// 继续通过out()访问软件支持的语言
g.V('javeme').out('created').out('implements').out('contains').out('supports') 

• 查询支持Gremlin语言的软件的作者

// 通过id找到“Gremlin”语言顶点
// 通过in()访问支持Gremlin的软件
// 继续通过in()访问软件的作者
g.V('4:Gremlin').in('supports').in('created')

• 查询某个作者的共同作者

// 通过id找到“javeme”作者顶点
// 通过out()访问其创建的软件
// 通过in()访问软件的所有作者
g.V('javeme').out('created').in('created')