局部理解WORD中的RANGE对象

分享]局部理解WORD中的RANGE对象

应网友之约，我做了一个局部的WORD中的RANGE对象的小例子，希望通过这个例子，有助于大家进一步理解WORD中的RANGE对象，以及该对象的RANGE方法、属性。

Sub ExampleByRange()
'假设文档的第一个段落为："1.大家好，我是来自EXCELHOME的守柔。"
'其中的1.不是自动编号产生的,也就是说,这个段落的起始字符为1,结束字符为段落结束标记(回车换行符)
'WORD中,每一个段落的起始位置和结束位置(段落标记)是动态的,是可能通过代码获知的
Dim myRange As Range, lngPostion As Long
Dim TempRange As Range
With ActiveDocument
Set myRange = .Paragraphs(1).Range
'这个定义相当于Set myRange = .Range(.Paragraphs(1).Range.Start, .Paragraphs(1).Range.End)
'显然,我们不会使用这个定义
MsgBox myRange
'此对话框中显示的文本为带有段落标记的第一个段落文本
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Set myRange = .Range(.Paragraphs(1).Range.Start, .Paragraphs(1).Range.End - 1)
MsgBox myRange
'此对话框将显示去除段落标记的第一段落中的文本
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'假如我要得到该段落的第一个字符的文本
Set myRange = .Paragraphs(1).Range
MsgBox myRange.Characters(1).Text
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'假如我要得到该段落的第一个词组的文本
Set myRange = .Paragraphs(1).Range
MsgBox myRange.Words(1).Text
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'假如我们要得到这个段落的前三个字符
Set myRange = .Paragraphs(1).Range
MsgBox .Range(myRange.Start, myRange.Start + 3)
'也可以这样:(setRange方法主要应用于已定义的Range对象后重设其位置)
Set myRange = .Paragraphs(1).Range
myRange.SetRange myRange.Start, myRange.Start + 3
MsgBox myRange
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'假如说我们有很多这样的段落,其中开头的序号是变化的,可能是1.,也可能是102.
'我们要取得.后面到段落标记前的文本,可以使用INSTR函数
Set myRange = .Paragraphs(1).Range
lngPostion = VBA.InStr(myRange, ".")
If lngPostion > 0 Then
MsgBox .Range(myRange.Start + lngPostion, myRange.End - 1)
End If
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'而有些时候,我们通常需要得到从段落标志向前的字符,如"守柔",就是EXCELHOME可能换成SOHU等
Set myRange = .Paragraphs(1).Range
MsgBox .Range(myRange.End - 4, myRange.End - 2)
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' 如果我们想把这段文字在第五个字符后插入一句话,如"THIS IS A TEST"
Set myRange = .Paragraphs(1).Range
'定义一个RANGE对象,这个对象这段落的前五个字符
Set TempRange = .Range(myRange.Start, myRange.Start + 5)
MsgBox TempRange
TempRange.InsertAfter "THIS A TEST"
'注意,这时Temprange对象已自动扩展,
MsgBox TempRange
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'如果我们想把这段文字在第五个字符后插入一句话,如"THIS IS A TEST",并且把这插入的字符加粗并设置为红色字体时
Set myRange = .Paragraphs(1).Range
以下重设RANGE对象时 , 其相当于一个插入点(光标状态), 即它的START属性 = END属性
myRange.SetRange myRange.Start + 5, myRange.Start + 5
myRange.InsertAfter "THIS A TEST"
With myRange.Font
.Bold = True
.Color = wdColorRed
End With
End With
End Sub

来自：http://club.excelhome.net/viewthread.php?tid=137935&replyID=&skin=0