《汇编语言》王爽著（第三版）实验七（个人方法记录）

话不多说直接上代码（没时间了）

assume cs:code, ds:data, es:table, ss:stack

data segment
    ;21年的21个字符串 (21*4*1 = 84byte) - 首地址为data:0H
    db '1975','1976','1977','1978','1979','1980','1981','1982','1983','1984','1985'
    db '1986','1987','1988','1989','1990','1991','1992','1993','1994','1995'

    ;21年每年公司总收入的21个dword (21*4 = 84byte) - 首地址为data:054H
    dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514,345980,590827
    dd 803530,1183000,1843000,2759000,3753000,4649000,5937000

    ;21年每年的公司雇员人数的21个word (21*2 = 42byte) - 首地址为data:0A8H
    dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
    dw 11542,14430,15257,17800
data ends

table segment
    db 21 dup ('year summ ne ?? ')
table ends

stack segment
    dw 8 dup (0)
stack ends

;代码段
code segment

    start:
        mov ax,data
        mov ds,ax
        mov ax,table
        mov es,ax

        mov si,0    ;原数据地址偏移
        mov di,0    ;目的地址偏移
        mov bx,0    

        mov cx,21
        s:
            ;复制年份
            mov ax,ds:[si]
            mov es:[di],ax
            mov ax,ds:[si+2]
            mov es:[di+2],ax

            ;复制每年公司总收入
            mov ax,ds:054H[si]
            mov es:05H[di],ax
            push ax                 ;压栈用来计算人均收入
            mov ax,ds:054H[si+2]
            mov es:05H[di+2],ax
            push ax                 ;压栈用来计算人均收入

            ;每年的公司雇员人数
            mov ax,ds:0A8H[bx]
            mov es:0AH[di],ax

            ;一年的一行数据复制完毕

            ;计算人均收入
            pop dx
            pop ax
            div word ptr es:0AH[di]
            mov word ptr es:0DH[di],ax       ;将商存入

            add si,4    ;si原数据的偏移,年份和收入单个数据长度4个字节所以加4
            add bx,2    ;bx因为人数单个数据长度2个字节所以加2
            add di,16   ;下一行
        loop s

        mov ax,4c00H
        int 21H

code ends

end start

结果如下：

巴萨比赛开始了，看比赛去了！！！