oracle blob&clob类型的字段插入字符串

Oracle数据库操作：Blob与Clob类型内容追加及插入

最新推荐文章于 2024-09-04 09:53:00 发布

原创最新推荐文章于 2024-09-04 09:53:00 发布 · 2.8k 阅读

7 ·

CC 4.0 BY-SA版权

文章标签：

#oracle #sql #数据库

数据库专栏收录该内容

8 篇文章

订阅专栏

这篇博客介绍了如何在Oracle数据库中使用DBMS_LOB包的WRITEAPPEND函数追加和插入Blob及Clob类型的数据。首先，创建了一个名为T_FIELDS的表，包含Blob、Clob和Nclob字段。然后，展示了将字符串转化为Blob并分段追加的详细过程，以及将字符串直接插入Clob字段的两种方式，包括常规写法和简便写法。最后，通过示例展示了如何将多个字符串拼接后一次性插入Clob字段。

函数说明

官方文档

-- BLOB类型追加，amount为要追加的字节数，buffer类型为RAW
DBMS_LOB.WRITEAPPEND (
   lob_loc IN OUT NOCOPY BLOB, 
   amount  IN BINARY_INTEGER, 
   buffer  IN RAW
); 

-- CLOB类型追加，amount为要追加的字符数，buffer类型为VARCHAR2
DBMS_LOB.WRITEAPPEND (
   lob_loc IN OUT NOCOPY CLOB CHARACTER SET ANY_CS, 
   amount  IN BINARY_INTEGER, 
   buffer  IN VARCHAR2 CHARACTER SET lob_loc%CHARSET
);

建一个表，用来测试

CREATE TABLE "T_FIELDS" (	
	"ID" NUMBER NOT NULL ENABLE, 
	"F_BLOB" BLOB, 
	"F_CLOB" CLOB, 
	"F_NCLOB" NCLOB, 
	 PRIMARY KEY ("ID")
);

将字符串插入Blob字段


---------------------------------------------------------------------
-- 将字符串插入Blob字段
---------------------------------------------------------------------
DECLARE
	content BLOB; -- 或者使用下面这种写法：表名.字段名%TYPE
	-- content T_FIELDS.F_BLOB%TYPE; -- Blob类型
	buff VARCHAR2(4000);
-- 	amount BINARY_INTEGER:=0;			-- amount := amount + LENGTHB(buff);

BEGIN
  	-- 初始化blob
	dbms_lob.createtemporary(content, true);
	-- 拼出4000个字符（注意：1个中文=2个字符）
	FOR i IN 1..1000 LOOP
		buff := buff||'1234';
	END LOOP;
	
	-- 向blob中追加内容，LENGTHB()取的是字节数，不是字符数，UTL_RAW.CAST_TO_RAW()将字符串转换为RAW
	dbms_lob.writeAppend(content, LENGTHB(buff), UTL_RAW.CAST_TO_RAW(buff));
	
	-- 如果字符串过长，需分为多次放入blob中，否则会超出varchar2的长度限制
	buff := '第二段字符串....省略一万字....';
	-- 再次向blob中追加内容
	dbms_lob.writeAppend(content, LENGTHB(buff), UTL_RAW.CAST_TO_RAW(buff));

	INSERT INTO "T_FIELDS" ("ID", "F_BLOB") VALUES (1, content);
	commit;
END;

将字符串插入Clob字段


---------------------------------------------------------------------
-- 将字符串插入Clob字段
---------------------------------------------------------------------
DECLARE
	content CLOB; -- 或者使用下面这种写法：表名.字段名%TYPE
	-- content T_FIELDS.F_CLOB%TYPE; -- Clob类型
	buff VARCHAR2(4000);

BEGIN
  	-- 初始化clob
	dbms_lob.createtemporary(content, true);
	-- 拼出4000个字符（注意：1个中文=2个字符）
	FOR i IN 1..1000 LOOP
		buff := buff||'1234';
	END LOOP;
	
	-- 向clob中追加内容，LENGTH()取的是字符数，此处不用字节数
	dbms_lob.writeAppend(content, LENGTH(buff), buff);
	
	-- 如果字符串过长，需分为多次放入clob中，否则会超出varchar2的长度限制
	buff := '第二段字符串....省略一万字....';
	-- 再次向clob中追加内容
	dbms_lob.writeAppend(content, LENGTH(buff), buff);

	INSERT INTO "T_FIELDS" ("ID", "F_CLOB") VALUES (2, content);
	commit;
END;

其实Clob还有种简便写法

---------------------------------------------------------------------
-- 将字符串插入Clob字段 （简便写法）
---------------------------------------------------------------------
DECLARE 
	-- content CLOB; -- 或者使用下面这种写法：表名.字段名%TYPE
	content T_FIELDS.F_CLOB%TYPE; -- Clob类型
	buff1 VARCHAR2(4000);
	buff2 VARCHAR2(4000);
BEGIN
	-- 拼出4000个字符（注意：1个中文=2个字符）
	FOR i IN 1..1000 LOOP
		buff1 := buff1 ||'1234';
		buff2 := buff2 ||'0987';
	END LOOP;
	
	-- 例如：通过这种拼接的方式给Clob变量赋值
	-- content := '第一段内容'||'第二段内容';

	content := buff1 || buff2;
	INSERT INTO "T_FIELDS" ("ID", "F_CLOB") VALUES (3, content);
	commit;
END;