asp之FSO大全

<%
Function ShowDriveInfo(strFolder)'显示磁盘信息
'strRootFolder="/"
'strDrivInfo=ShowDriveInfo(strRootFolder)
'Response.Write(strDrivInfo)
Dim strTestFolder,objFSO,objDrive,strDriveInfo
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strTestFolder=Server.Mappath(strFolder)
Set objDrive=objFSO.GetDrive(objFSO.GetDriveName(strTestFolder))
strDriveInfo="Web服务器根目录："&objDrive.VolumeName&"<br>"
strDriveInfo=strDriveInfo&"磁盘代号："&objDrive.DriveLetter&"<br>"
strDriveInfo=strDriveInfo&"磁盘序列号："&objDrive.SerialNumber&"<br>"
strDriveInfo=strDriveInfo&"磁盘类型："&objDrive.Drivetype&"<br>"
strDriveInfo=strDriveInfo&"文件系统："&objDrive.FileSystem&"<br>"
strDriveInfo=strDriveInfo&"总容量："&FormatNumber(objDrive.TotalSize/1024,0)&"KB<br>"
strDriveInfo=strDriveInfo&"可用空间："&FormatNumber(objDrive.FreeSpace/1024,0)&"KB<br>"
ShowDriveInfo=strDriveInfo
set objDrive=nothing
set objFSO=nothing
end Function
Function ShowFolderList(strFolder)'显示Web服务器根目录和相关信息
Dim strTestFolder,objFSO,objRootFolder,objFolder,strFolderList
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strTestFolder=Server.MapPath(strFolder)
Set objRootFolder=objFSO.Getfolder(strTestFolder)
For Each objFolder in objRootFolder.SubFolders
   strFolderList=strFolderList&objFolder.name
   strFolderList=strFolderList&"<br>"
Next
ShowFolderList=strFolderList
Set objRootFolder=Nothing
Set objFSO=Nothing
end Function
Function ShowFolderInfo(strFolder)'显示文件夹信息
Dim strTestFolder,objFSO,objFolder,strFolderInfo
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strTestFolder=Server.MapPath(strFolder)
Set objFolder=ObjFSO.GetFolder(StrTestFolder)
strFolderInfo="Web服务器目录："&UCase(strTestFolder)&"<br>"
strFolderInfo=strFolderInfo&"名称："&objFolder.Name&"<br>"
strFolderInfo=strFolderInfo&"属性："&objFolder.Attributes&"<br>"
strFolderInfo=strFolderInfo&"创建时间："&objFolder.DateCreated&"<br>"
strFolderInfo=strFolderInfo&"访问时间："&objFolder.DateLastAccessed&"<br>"
strFolderInfo=strFolderInfo&"修改时间："&objFolder.DateLastModified&"<br>"
strFolderInfo=strFolderInfo&"大小："&FormatNumber(objFolder.Size/1024,0)&"KB<br>"
ShowFolderInfo=strFolderInfo
Set objFolder=Nothing
Set objFSO=Nothing
End Function
Function CreateFolder(strFolder)'创建文件夹(返回值0，创建失败；1：创建成功)
Dim strTestFolder,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strtestFolder) Then
   CreateFolder=0
Else
   objFSO.CreateFolder(strTestFolder)
   CreateFolder=1
End if
Set objFSO=Nothing
End Function
Function CheckFolderExists(strFolder)'检查文件夹是否存在(返回值0，不存在；1：存在)
Dim strTestFolder,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strTestFolder) Then
   CheckFolderExists=1
Else
   CheckFolderExists=0
End if
Set objFSO=Nothing
End Function
Function DeleteFolder(strFolder)'删除文件夹(返回值0，删除失败；1：删除成功)
Dim strTestFolder,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strtestFolder) Then
   objFSO.DeleteFolder(strTestFolder)
   DeleteFolder=1
Else
   DeleteFolder=0
End if
Set objFSO=Nothing
End Function
Function MoveFolder(strFolder,strFolder1)'移动文件夹(返回值0，移动失败；1：移动成功)
Dim strTestFolder,strTestFolder1,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
strTestFolder1=Server.MapPath(CStr(strFolder1))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strTestFolder) Then
   If objFSO.FolderExists(strTestFolder1) Then
    MoveFolder=0
   Else
    objFSO.MoveFolder strTestFolder,strTestFolder1
    MoveFolder=1
   End if
Else
   MoveFolder=0
End if
Set objFSO=Nothing
End Function
Function CopyFolder(strFolder,strFolder1)'复制文件夹(返回值0，复制失败；1：复制成功)
Dim strTestFolder,strTestFolder1,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
strTestFolder1=Server.MapPath(CStr(strFolder1))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strTestFolder) Then
   If objFSO.FolderExists(strTestFolder1) Then
    CopyFolder=0
   Else
    objFSO.CopyFolder strTestFolder,strTestFolder1
    CopyFolder=1
   End if
Else
   CopyFolder=0
End if
Set objFSO=Nothing
End Function
Function ShowFileList(strFolder)'显示Web服务器目录的文件
Dim strTestFolder,objFSO,objFolder,objFile,strFileList
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strTestFolder=Server.MapPath(strFolder)
Set objFolder=objFSO.GetFolder(strTestFolder)
For Each objFile in objFolder.Files
   strFileList=strFileList&objFile.name
   strFileList=strFileList&"<br>"
Next
ShowFileList=strFileList
Set objFolder=Nothing
Set objFSO=Nothing
End Function
Function ShowFileInfo(strFile)'显示文件信息
Dim objFSO,objFile,strFileInfo
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strFile=Server.MapPath(strFile)
Set objFile=objFSO.GetFile(strFile)
strFileInfo="文件名："&objFile.Name&"<br>"
strFileInfo=strFileInfo&"类型："&objFile.Type&"<br>"
strFileInfo=strFileInfo&"位置："&objFile.Path&"<br>"
strFileInfo=strFileInfo&"属性："&objFile.Attributes&"<br>"
strFileInfo=strFileInfo&"创建时间："&objFile.DateCreated&"<br>"
strFileInfo=strFileInfo&"访问时间："&objFile.DateLastAccessed&"<br>"
strFileInfo=strFileInfo&"修改时间："&objFile.DateLastModified&"<br>"
strFileInfo=strFileInfo&"大小："&FormatNumber(objFile.Size/1024,0)&"KB<br>"
ShowFileInfo=strFileInfo
Set objFile=Nothing
Set objFSO=Nothing
End Function
Function CreateFile(strFile)'创建文件(返回值0，创建失败；1：创建成功)
Dim strTestFile,objFSO,objStream
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
   CreateFile=0
Else
   Set objStream=objFSO.CreateTextFile(strTestFile,True)
   CreateFile=1
   Set objStream=Nothing
End if
Set objFSO=Nothing
End Function
Function CheckFileExists(strFile)'检查文件是否存在(返回值0，不存在；1：存在)
Dim strTestFile,objFSO
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
   CheckFileExists=1
Else
   CheckFileExists=0
End if
Set objFSO=Nothing
End Function
Function DeleteFile(strFile)'删除文件(返回值0，删除失败；1：删除成功)
Dim strTestFile,objFSO,objFile
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
   Set objFile=objFSO.GetFile(strTestFile)
   objFile.Delete
   DeleteFile=1
   Set objFile=Nothing
Else
   DeleteFile=0
End if
Set objFSO=Nothing
End Function
Function MoveFile(strFile,strPath)'移动文件(返回值0，移动失败；1：移动成功)
Dim strTestFile,strTestPath,objFSO,objFile
strTestPath=Server.MapPath(strPath)
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
   Set objFile=objFSO.GetFile(strTestFile)
   objFile.Move(strTestPath&"/"&objFile.Name)
   MoveFile=1
   Set objFile=Nothing
Else
   MoveFile=0
End if
Set objFSO=Nothing
End Function
Function CopyFile(strFile,strPath)'复制文件(返回值0，复制失败；1：复制成功)
Dim strTestFile,strTestPath,objFSO,objFile
strTestPath=Server.MapPath(strPath)
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
   Set objFile=objFSO.GetFile(strTestFile)
   objFile.Copy(strTestPath&"/"&objFile.Name)
   CopyFile=1
   Set objFile=Nothing
Else
   CopyFile=0
End if
Set objFSO=Nothing
End Function
Function RanameFile(strFile,strNewFile)'重命名文件(返回值0，重命名失败；1：重命名成功)
'strFile为源文件，包括路径
'strNewFile重命名后的文件，只有文件名
Dim strTestFile,strTestPath,objFSO,objFile
strTestFile=Server.MapPath(strFile)
strTestPath=Left(strTestFile,InStrRev(strTestFile,"\"))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
Set objFile=objFSO.GetFile(strTestFile)
objFile.Move(strTestPath&strNewFile)
RanameFile=1
Set objFile=Nothing
Else
RanameFile=0
End if
Set objFSO=Nothing
End Function
Function ReadTextFile(strFile)'读取文件的内容
Dim strTestFile,objFSO,objInStream,ForReading
ForReading=1
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objInStream=objFSO.OpenTextFile(strTestFile,ForReading,False,False)
ReadTextFile=objInStream.ReadAll
objInStream.Close
Set objInStream=Nothing
Set objFSO=Nothing
End Function
Sub SaveTextFile(strFile,strFileIn)'保存文件的内容
Dim strTestFile,objFSO,objOutStream,ForWriting
ForWriting=2
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objOutStream=objFSO.OpenTextFile(strTestFile,ForWriting,True,False)
objOutStream.WriteLine(strFileIn)
objOutStream.Close
Set objOutStream=Nothing
Set objFSO=Nothing
End Sub
Sub AppendTextFile(strFile,strAppendLine)'添加文件的内容
Dim strTestFile,objFSO,objOutStream,ForAppending
ForAppending=8
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objOutStream=objFSO.OpenTextFile(strTestFile,ForAppending,True,False)
objOutStream.WriteLine(strFileIn)
objOutStream.Close
Set objOutStream=Nothing
Set objFSO=Nothing
End Sub
Function SearchTextFile(strFile,strSearchText)'查找文本文件的字符串(返回值0，字符串不存在；1：字符串存在)
Dim strTestFile,objFSO,objInStream,strFileContents,isFound,ForReading
isFound=0
ForReading=1
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objInStream=objFSO.OpenTextFile(strTestFile,ForReading,False,False)
strFileContents=objInStream.ReadALL
If InStr(1,strFileContents,strSearchText,1) Then
   isFound=1
End if
objInStream.Close
Set objInStream=Nothing
Set objFSO=Nothing
SearchTextFile=isFound
End Function
Function ReplaceTextFile(strFile,strSearchText,strReplaceText)'查找和替换文本文件的字符串
Dim strTestFile,objFSO,objInStream,objOutStream,strFileContents,isFound,ForReading,ForWriting
Dim strInLine,strLeft,strRight,intPos,intBegin
isFound=0
ForReading=1
ForWriting=2
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objInStream=objFSO.OpenTextFile(strTestFile,ForReading,False,False)
strFileContents=""
Do while Not objInStream.AtEndOfStream
   strInLine=objInstream.ReadLine
   intPos=1
   Do
    intBegin=intPos
    intPos=Instr(intBegin,strInLine,strSearchText,1)
    If intPos>0 then
     strLeft=Left(strInLine,intPos-1)
     strRight=Right(strInLine,Len(strInline)-intPos-Len(strSearchText)+1)
     strInLine=strLeft&strReplaceText&strRight
     isFound=isFound+1
    Else
     strFileContents=strfileContents&strInLine&Chr(13)&Chr(10)
    End if
   Loop While intPos<>0
Loop
objInStream.Close
Set objInStream=Nothing
Set objOutStream=objFSO.OpenTextFile(strTestFile,ForWriting,True,False)
objOutStream.WriteLine(strFileContents)
objOutStream.Close
Set objOutStream=Nothing
Set objFSO=Nothing
ReplaceTextFile=isFound
End Function
%>

转载于:https://www.cnblogs.com/lykouyi/p/5687844.html