迈出万物互联的一小步:仓颉版TCPGroupChat群聊实现

1 概述

1.1 案例介绍

TCPGroupChat基于TCP协议实现了一个群聊系统的核心功能。程序启动后,会监听指定端口并持续等待客户端连接。每当有新客户端接入时,服务器会创建一个独立的线程专门用于接收该客户端发送的消息,并将这些消息暂存到一个无阻塞队列中。服务器主循环从队列中取出消息后,利用互斥锁保护成员列表,并向所有其他客户端广播该消息,同时自动清理掉线客户端连接。这种多线程加队列的设计实现了并发处理多个客户端的能力,确保了通信的实时性和稳定性。

客户端工作机制 客户端程序负责与服务器建立连接,并实现双向通信。一方面,它通过子线程持续监听来自服务器的消息,并将其解码后打印在控制台,以便用户查看;另一方面,主循环不断读取用户的键盘输入,并将每条输入内容发送给服务器,从而实现发送消息的功能。如果检测到网络异常或服务器断开连接,客户端会自动退出程序,以避免死循环和资源泄漏。这种设计保证了客户端能够稳定地收发数据,并及时响应连接状态变化。

TCPGroupChat体现了典型的C/S架构在网络通信中的应用,适用于需要集中管理、实时交互的场景,如即时通讯、在线协作等。服务器作为中心节点统一处理消息转发,既简化了客户端逻辑,又提升了系统的可扩展性。此外,使用多线程处理并发请求、结合同步机制保障数据一致性,是构建健壮网络服务的重要手段。本示例虽然为简易群聊系统,但其结构清晰、逻辑完整,对大家熟悉CodeArts IDE for Cangjie具备良好的教学价值和工程参考意义。

1.2 适用对象

  • 企业
  • 个人开发者
  • 高校学生

1.3 案例时间

本案例总时长预计40分钟。

1.4 案例流程

d071634d5777d6486d97c29f899a93c6.png

说明:

  1. 练习使用CodeArts IDE for Cangjie编辑器;
  2. 仓颉创建TCPGroupChat群聊并体验。

1.5 资源总览

资源名称规格单价(元)时长(分钟)
华为开发者空间——云主机鲲鹏通用计算增强型 kc2 | 4vCPUs | 8G | Ubuntu免费40

最新案例动态,请查阅 《迈出万物互联的一小步:仓颉版TCPGroupChat群聊实现》。小伙伴快来领取华为开发者空间,进入云主机桌面版实操吧!

2 运行测试环境准备

2.1 开发者空间配置

面向广大开发者群体,华为开发者空间提供一个随时访问的“开发桌面云主机”、丰富的“预配置工具集合”和灵活使用的“场景化资源池”,开发者开箱即用,快速体验华为根技术和资源。

领取云主机后可以直接进入华为开发者空间工作台界面,点击打开云主机 > 进入桌面连接云主机。

a1aae6ff53aac98855ef597dd6899967.png

552fc96c3b58a06e294e4a760ae719e3.PNG

2.2 创建仓颉程序

点击桌面CodeArts IDE for Cangjie,打开编辑器,点击新建工程,保持默认配置,点击创建。

产物类型说明:

  • executable,可执行文件;
  • static,静态库,是一组预先编译好的目标文件的集合;
  • dynamic,动态库,是一种在程序运行时才被加载到内存中的库文件,多个程序共享一个动态库副本,而不是像静态库那样每个程序都包含一份完整的副本。

28acbca9146a8a6aacbfdd4f6ac3791b.png

2.3 运行仓颉工程

创建完成后,打开src/main.cj,参考下面代码简单修改后,点击编辑器右上角运行按钮直接运行,终端窗口可以看到打印内容。

package demo
// 第一个仓颉程序
main(): Int64 {
    println("hello world")
    println("你好,仓颉!")
    return 0
}

(* 仓颉注释语法:// 符号之后写单行注释,也可以在一对 /* 和 */ 符号之间写多行注释)

d1e16b48f5f9620fafe9fc59ae62a367.png

到这里,我们第一个仓颉程序就运行成功啦!接下来我们继续探索仓颉语言。

3 仓颉实现TCPGroupChat群聊

3.1 创建聊天服务器

首先,我们要明确,想实现一个群聊服务器,那么服务器需要以下功能才能支持群聊:

1.需要应对可能出现的并发情况。

2.需要聊天界面进行输入输出

3.需要网络通信工具支持

4.群聊成员的信息需要同步更新处理

5.服务器需要实时中转群聊成员的消息

6.可以支持退出(关闭)群聊

当我们明确了我们的服务器应该具备的功能,那么我们就可以着手去写我们的服务器了。在CodeArts IDE for Cangjie中创建服务端源文件server.cj,下面对服务端代码拆分解释,完整server.cj代码再3.1章节末尾。

3.1.1 导入模块与全局配置
import std.collection.*
import std.collection.concurrent.*
import std.console.*
import std.socket.*
import std.sync.*
import std.time.Duration

const PORT: UInt16 = 24621
const BUFFER_SIZE = 1024
var g_quit = false

其中,collection.*为仓颉的基础集合库,collection.concurrent.*为并发安全所需要的集合库,std.console.*库用于支持控制台输入输出。std.socket.*模块用于支持网络通信,具备TcpSocket等工具。std.sync.*和std.time.Duration分别用于同步和时间处理。通过导入以上模块,我们导入了网络通信、线程同步的能力。

我们定义服务监听端口为24621,接收消息缓冲区大小为1024,可以修改,但是需要权衡内存与消息长度。并且定义全局退出标志g_quit = false,通过简单布尔值控制多线程退出。

3.1.2 控制台退出指令监听
func controller() {
    spawn {
        while (!g_quit) {
            let key = Console.stdIn.read().getOrDefault {r' '}
            if (key == r'q' || key == r'Q') {
                g_quit = true
            }
        }
    }
}

我们通过定义一个controller函数来控制退出行为。其中,通过while循环,后台线程持续监听用户输入,输入q/Q时终止服务。

通过spawn创建轻量级协程(划重点,后面要考),避免阻塞主线程。

3.1.3 TCP Socket扩展方法

在正常的网络通信中,我们不能保证通信连接时时刻刻都是理想状态,网络通信中连接可能随时中断,直接调用write可能导致程序崩溃,所以我们需要给TcpSocket添加扩展:

extend TcpSocket {
    public func tryWrite(data: Array<Byte>) {
        try { 
            this.write(data)  
        } catch (e: SocketException) {
            if (!this.isClosed())  { this.close()  }
            return false
        }
        return true
    }
} 

为了避免未处理异常导致程序崩溃,我们在TcpSocket扩展方法中对原生write方法进行包装,捕获 SocketException 异常(如连接中断、超时等),同时通过(if (!this.isClosed()) { this.close() }),当写入失败时主动关闭无效连接,防止后续无效操作占用资源。

3.1.4 主程序模块

首先,在主程序main()中进行初始化和资源创建

    let messages = NonBlockingQueue<(TcpSocket, Array<Byte>)>()// 线程安全消息队列
    let members = LinkedList<TcpSocket>() // 群聊成员-客户端
    let server = TcpServerSocket(bindAt: PORT) // 服务端
    server.bind()// 绑定端口
    controller()// 启动控制台监听

通过NonBlockingQueue无锁设计提升并发性能,存储待转发的messages(客户端, 消息)元组。通过LinkedList存储所有客户端连接。

之后我们构建客户端连接处理线程

// 和新的客户端建立连接
    let mutex = ReentrantMutex()
    let monitor = Monitor()
    spawn {
        while (!g_quit) {
            let client = server.accept()// 阻塞等待新连接
            synchronized (mutex) {
                members.append(client)// 线程安全添加成员
            }
            // 每个连接要处理的任务
            spawn {// 为每个客户端创建消息接收线程
                while (!g_quit) {
                    let data = Array<Byte>(BUFFER_SIZE, item: 0)
                    // 初始化缓冲区
                    try { client.read(data) } catch (e: SocketException) {
                        return // 遇到异常终止此线程,由转发线程清理资源
                    }
                    println(String.fromUtf8(data))
                    // 服务端日志打印
                    messages.enqueue((client, data))
                    // 消息入队
                    synchronized (monitor) { monitor.notify() }
                    // 唤醒转发线程
                }
            }
        }
    }

在这里我们为了要实现连接对应线程,需要通过双重spawn。同时,为了进一步优化效率,我们利用monitor.notify()通知转发线程有新消息,避免忙等待,进一步实现CPU优化。并且当捕捉到异常时,终止线程,由转发线程清理资源。

我们现在进行下一步,搭建消息转发以及连接维护模块,将接收到的消息广播给所有在线客户端,同时动态维护有效的客户端连接池。

// 转发消息到所有客户端,实现群聊
    while (!g_quit) {
        // 此处 Monitor 仅用于避免 while 空转,可以注释掉以下三行代码对比进程 CPU 消耗情况
        synchronized (monitor) {
            monitor.wait(timeout: Duration.millisecond * 100)            
        }
        while (let Some((client, data)) <- messages.dequeue()) {
            mutex.lock()
            // 遍历群聊成员,转发消息并清理无效客户端
            members.removeIf { socket =>
                if (refEq(client, socket)) { // 不必转发给消息源
                    return false
                }
                !socket.tryWrite(data)
            }
            mutex.unlock()
        }
    }

首先是外层循环控制 (while (!g_quit)),监听全局退出标志 g_quit。但是考虑到持续监听会有资源浪费,我们最理想的状态是当消息传过来时进行监听,其余时间不进行监听,所以我们可以使用Monitor 同步等待 (synchronized (monitor)),当消息队列为空时,通过 wait 让出CPU资源,降低无意义循环的消耗,避免cpu空转。接下来,我们需要完成消息转发部分,我们通过messages.dequeue() 从线程安全队列获取待转发消息同时为了确保模式匹配类型安全,我们使用Some((client, data))。为了保证对 members 链表的操作(遍历/修改)线程安全,避免并发修改异常,我们需要引用互斥锁mutex.lock() 。为了避免无效转发,进行选择性广播,在这里我们使用refEq(client, socket) 跳过消息发送者自身(避免回显)。通过tryWrite(data) 尝试写入,失败返回 false 触发移除逻辑。为了清理失效连接,removeIf 在遍历期间直接移除写入失败的客户端,保持连接池健康。

最后,我们来构建最后一个退出模块。

// 退出时通知所有客户端
    for (client in members) {
        if (client.tryWrite("Server Exit".toArray())) {
            client.close()
        }
    }
    server.close()

最后,我们来构建最后一个退出模块。通过for (client in members)

遍历客户端连接。通过client.tryWrite(“Server Exit”.toArray())发送退出通知。其中的tryWrite扩展方法可以确保写入安全。写入成功之后执行 close(),避免重复关闭已失效的连接。最后关闭服务器server.close()。好了,现在我们拥有了一个完整的客户端服务器:

// 群聊程序-服务器完整代码

// 群聊程序-服务器完整代码
import std.collection.*
import std.collection.concurrent.*
import std.console.*
import std.socket.*
import std.sync.*
import std.time.Duration

const PORT: UInt16 = 24621
const BUFFER_SIZE = 1024
var g_quit = false

// 从控制台读取退出命令
func controller() {
    spawn {
        while (!g_quit) {
            let key = Console.stdIn.read().getOrDefault {r' '}
            if (key == r'q' || key == r'Q') {
                g_quit = true
            }
        }
    }
}

extend TcpSocket {
    public func tryWrite(data: Array<Byte>) {
        try { this.write(data) } catch (e: SocketException) {
            if (!this.isClosed()) { this.close() }
            return false
        }
        return true
    }
}

main() {
    let messages = NonBlockingQueue<(TcpSocket, Array<Byte>)>()
    let members = LinkedList<TcpSocket>() // 群聊成员-客户端
    let server = TcpServerSocket(bindAt: PORT) // 服务端
    server.bind()
    controller()

    // 和新的客户端建立连接
    let mutex = ReentrantMutex()
    let monitor = Monitor()
    spawn {
        while (!g_quit) {
            let client = server.accept()
            synchronized (mutex) {
                members.append(client)
            }
            // 每个连接要处理的任务
            spawn {
                while (!g_quit) {
                    let data = Array<Byte>(BUFFER_SIZE, item: 0)
                    try { client.read(data) } catch (e: SocketException) {
                        return // 遇到异常终止此线程,由转发线程清理资源
                    }
                    println(String.fromUtf8(data))
                    messages.enqueue((client, data))
                    synchronized (monitor) { monitor.notify() }
                }
            }
        }
    }

    // 转发消息到所有客户端,实现群聊
    while (!g_quit) {
        // 此处 Monitor 仅用于避免 while 空转,可以注释掉以下三行代码对比进程 CPU 消耗情况
        synchronized (monitor) {
            monitor.wait(timeout: Duration.millisecond * 100)            
        }
        while (let Some((client, data)) <- messages.dequeue()) {
            mutex.lock()
            // 遍历群聊成员,转发消息并清理无效客户端
            members.removeIf { socket =>
                if (refEq(client, socket)) { // 不必转发给消息源
                    return false
                }
                !socket.tryWrite(data)
            }
            mutex.unlock()
        }
    }
    // 退出时通知所有客户端
    for (client in members) {
        if (client.tryWrite("Server Exit".toArray())) {
            client.close()
        }
    }
    server.close()
}

3.2 创建群聊客户端

既然我们已经实现了一个群聊服务器,那么同样,客户端也需要以下功能才能支持群聊:

1. 网络通信能力。

2. 需要聊天界面进行输入输出

3. 需要与服务器能够进行连接

4. 能够有退出群聊的能力

在CodeArts IDE for Cangjie中创建服务端源文件client.cj,下面对客户端代码拆分解释,完整client.cj代码再3.2章节末尾。

3.2.1 导入与常量定义
import std.socket.*
import std.console.*

const IP = "127.0.0.1"// 服务器地址(本地回环)
const PORT: UInt16 = 24621// 与服务端一致的端口
const BUFFER_SIZE = 1024// 接收缓冲区大小
var g_quit = false// 全局退出标志

其中,std.console.*库用于支持控制台输入输出。std.socket.*模块用于支持网络通信,具备TcpSocket等工具。通过导入以上模块,我们导入了网络通信、控制台交互的能力。

同时我们也定义IP和端口,与服务器保持一致。

3.2.2 主程序模块

先建立socket连接

let socket = TcpSocket(IP, PORT)
socket.connect()

在客户端中,需要读取服务器同步发来的信息。

// 读取服务器发来的消息
    spawn {
        while (!g_quit) {
            let data = Array<Byte>(BUFFER_SIZE, item: 0)
            var count = 0
            // 如果对端正常关闭连接,不会抛出异常,read 返回 0
            try { count = socket.read(data) } catch (e: SocketException) {
                g_quit = true
            }
            if (g_quit || count == 0) { break }
            println(String.fromUtf8(data))
        }
}

在这个功能中,我们需要先完成线程分离,即通过spawn将接收逻辑与用户输入解耦,避免阻塞主线程。再通过捕获SocketException并设置退出标志,防止线程僵死,完成异常处理模块。同时通过count == 0进行连接关闭检测。

消息发送模块

// 向服务器发送消息
    while (!g_quit) {
        let input = Console.stdIn.readln().getOrDefault {"\n"}
        try { socket.write(input.toArray()) } catch (e: SocketException) {
            g_quit = true
        }
    }
    socket.close()

在消息发送模块中,通过while (!g_quit)持续监听用户输入,

首先通过readln获取控制台输入,getOrDefault提供默认值避免空指针,完成用户输入部分。为了实现同步发送数据我们需要使用socket.write(),,若连接已断开会抛出 SocketException,同时设置 g_quit = true,触发后续资源释放。最后通过socket.close()完成资源释放。

好啦,我们也完成了客户端的构建,可以尝试我们的群聊服务器啦!

// 群聊程序-客户端完整代码
import std.socket.*
import std.console.*

const IP = "127.0.0.1"
const PORT: UInt16 = 24621
const BUFFER_SIZE = 1024
var g_quit = false

main() {
    let socket = TcpSocket(IP, PORT)
    socket.connect()
    // 读取服务器发来的消息
    spawn {
        while (!g_quit) {
            let data = Array<Byte>(BUFFER_SIZE, item: 0)
            var count = 0
            // 如果对端正常关闭连接,不会抛出异常,read 返回 0
            try { count = socket.read(data) } catch (e: SocketException) {
                g_quit = true
            }
            if (g_quit || count == 0) { break }
            println(String.fromUtf8(data))
        }
    }
    // 向服务器发送消息
    while (!g_quit) {
        let input = Console.stdIn.readln().getOrDefault {"\n"}
        try { socket.write(input.toArray()) } catch (e: SocketException) {
            g_quit = true
        }
    }
    socket.close()
}

3.3 启动群聊

使用CodeArts IDE for Cangjie完成构建客户端程序client.cj和服务器程序server.cj后,右键server.cj选择“打开所在的文件夹”进入项目目录:

2e59588c639399b188dcf368fd4ae8c7.png

在项目目录右键选择“Open Terminal Here”进入终端:

5669b712858c83de91ac02a88470b194.png

(* 注意:项目目录已个人实际项目目录为准)

对client.cj和server.cj进行编译:

cjc client.cj -o client.exe

cjc server.cj -o server.exe

49d05779496e96493b123007d3b7d00c.png

0365164549939350b26cf221cc13df6f.png

启动客户端和服务端的过程中,必须首先启动服务端,如果首先启动客户端,则会报错:

19ecd5bda59d6f50cda715ba887f1232.png

先启动服务端:

b759dbb2b172b708ffdeca7ac55a29a8.png

如果多开服务端则会提示报错:

e67f146fe4deb6a72c237c2c175a05c2.png

新打开一个终端,启动客户端:

94401085215ebf697e906c78dafb979e.png

但可以多开客户端,组成群聊成员:

e6ec34b0f5b05a1d546d6a9370c3625b.png

查看针对协程进行优化的代码部分,即Monitor 同步等待 (synchronized (monitor)):

7fb354147a492e5e4369392ec81422d9.png

删去这三段代码之前,不进行通信时,CPU 99.3%空闲,CPU负载非常低。

97878996d1a2cb8503a5a4b5a3ada4ca.png

通信的时候,负载升高,CPU 47.0%空闲,CPU负载较高

e98bc86ba0483a070077e6da8f5f3ddb.png

删去此三段代码之后,重新创建群聊。不进行通信时,CPU 0%空闲,CPU负载几乎占满。

0a34b5136305844d66cbb467acf68e3c.png

通信过程演示客户端发送信息:

7f74ddfb8e2aea732c0c8a87f5b9d492.png

消息首先会从客户端发送到服务端,服务端显示客户端发送的消息:

ebe5ec7d47ca6769e28ecf41e6e8f51c.png

服务端会将消息分发到处于群聊中的所有客户端,此时客户端二号和客户端三号也都受到了客户端一号发送的消息:

b6fcd2043f8e2346e85d7ebb750ffcd5.png

当单独在服务端发送信息时:

d0c7bc39679e1f3fafffd824eba22272.png

但是因为没有通过客户端发送到服务端,所以其他客户端都没有收到信息:

917ba582947c7ffb228ef95832e547fa.png

退出通信,通过在服务端发送q或Q来终止群聊:

c54acd7bb5c5970477edca7d1341228e.png

此时客户端显示服务退出

a071e533d5afe630b1ee0578d84dfedb.png

此时所有端口均退出群聊

1f757404c56219b5b44ad75c34eda01f.png

此刻,您已掌握仓颉TCPGroupChat的核心功能,它将成为您探索仓颉世界的桥梁,助力探索仓颉语言的无限可能。

相关推荐

鸿蒙案例上新啦 | 购物、听歌、健身:15个模板带你一键激活社交娱乐

页面层级如何组织、跨页共享状态如何同步、列表与详情及个人中心如何形成稳定闭环。鸿蒙开发实践中心将这些高频消费与互动场景沉淀为可参考的标准模板,提供从业务架构到界面实现的快捷实践入口。更多实战案例欢迎前往鸿蒙开发实践中心案例中心查看并开启云端体验。

华为云官方博客 385

鸿蒙案例上新啦 | 出门打车、到家上课:25个模板带你一屏打通日常生活

如何合理拆分页面组件、如何建立单一可信的状态源、如何让用户在每一步操作中都获得明确反馈。鸿蒙开发实践中心以标准化的应用与元服务模板为入口,将清晰的业务架构与可复用的代码结构直观呈现。不妨立即挑选一个感兴趣的方向进入云端环境,从页面布局、组件封装、状态管理到路由组织,亲手跑通你的鸿蒙实战项目。

华为云官方博客 359

LakeAgent:DWS数据仓库的第二大脑,告别 “翻译式运维”,迈入智能自治时代

和普通 SQL 改写工具不同,LakeAgent 自动做多方案代价对比,主动规避负优化陷阱:补充分区键过滤实现剪枝,扫描分区由 37 收敛至 1,执行代价从 758.28 降至 113.74;未来的数据仓库,将不止能算、能存,更能看懂自己、诊断自己、理解自己。长久以来,数仓的智能都依附于人:信号需要人解读,瓶颈需要人研判,经验困在个体里,无法随底座永续生长。CPU 高、CPU 告警、CPU 诊断、CPU 使用率过高、CPU 满。语法、错误码、计费、性能调优、最佳实践、故障处置等全场景内容。

华为云官方博客 581

如何使用RDS Supabase后端BaaS能力:文件存储(File Storage)

• product-images(公开桶,允许公共读取):策略名称"Public read for product-images",允许SELECT,目标角色anon,策略定义bucket_id = 'product-images'。上传/删除需另配INSERT/DELETE策略,详见SQL。• product-specs(私有桶,仅认证用户访问自己的文件夹):建议拆为上传、读取、删除三条策略,策略定义均为 bucket_id = 'product-specs' 且仅限本人文件夹(详见下文 SQL)。

华为云官方博客 499

如何使用RDS Supabase后端BaaS能力:实时订阅与推送(Realtime)

Realtime 把数据库的每次变更同步到客户端:表里增、删、改一行,订阅者无需刷新页面或主动请求即可秒级收到。三大能力各司其职:• Postgres Changes — 监听表的 INSERT/UPDATE/DELETE,变化即通知• Broadcast — 客户端之间直接互发,适合瞬时通知、协同编辑• Presence — 跟踪频道里“谁在线”典型场景有实时数据展示(订单、库存、监控指标即时刷新)、即时通讯(消息收发、在线名单、“对方正在输入”)、协同编辑与实时通知。

华为云官方博客 490

AI Agent如何通过MCP连接到华为云RDS Supabase应用平台

Schema元数据列出所有可访问的表(按schema分组)。Schema元数据列出表的列及元数据(类型/默认值/约束)。Schema元数据列出所有约束(PK/FK/UNIQUE/CHECK/EXCLUDE)。可按schema/表/类型过滤。Schema元数据列出所有外键关系。可按schema/表过滤。Schema元数据列出所有索引及定义和大小。可按schema/表过滤。Schema元数据列出已应用的数据库迁移记录。Schema元数据列出已安装的PostgreSQL扩展。

华为云官方博客 494

华为大数据Flink让每一 CU 算力,跑出开源 5.74 倍的性能

1. 开源Apache Flink 已成为业界流计算事实标准,但在极端重负载场景下存在性能瓶颈。2. 华为大数据Flink通过多项自研深度优化,在执行计划、算子执行、状态存储三个层面构建协同的优化体系。3. Nexmark Benchmark 测试结果:整体性能提升 5.74 倍,极端重负载场景性能领先最高 18.3 倍。4. 100% 兼容 Apache Flink 1.20,业务代码零改造,无缝迁移。

华为云官方博客 398

LakeAgent实战 | 业务分析篇从一句提问到业务分析

本文以“订单金额变化”分析为例,展示LakeAgent如何通过自然语言提问,结合DataArtsStudio的数据资产与专业技能,帮助业务人员快速定位数据、生成SQL、追踪血缘、生成报告。从问题出发,逐步实现数据发现、变化洞察、原因追溯与团队协作,最终形成可复用的分析流程与企业规则,显著提升数据分析效率与一致性。

华为云官方博客 406

华为云RDS Supabase AI应用已开放公测 :30分钟搭建AI应用后端

认证、存储、实时推送、数据库API——4个后端模块,传统开发需要数周。今天,你只需要30分钟。AI创业公司的全栈开发工程师。上周老板说"下周要上线的AI对话应用,后端你来搞"——认证鉴权、数据库接口、文件存储、实时推送,每一个模块都需要数周搭建,而市场不会等你。小张打开华为云RDS Supabase,30分钟搭好认证、数据库API、对象存储,剩下的时间全用来打磨AI交互体验。基于开源Supabase+华为云RDS PostgreSQL全托管能力,为开发者提供。

华为云官方博客 412

如何使用RDS Supabase后端BaaS能力:数据库函数(Database Function)

上一篇介绍了 Database Data API——建表即自动生成增删改查接口,解决单表读写,但聚合统计、跨表事务、字段自动维护等逻辑已超出其能力边界。本篇推进到数据库函数(Database Function):把业务逻辑封装进数据库,前端通过 .rpc() 调用,由触发器自动响应数据变更。上一篇中,小张基于 Data API 完成了产品目录的建表与基础读写。但新需求随之而来:按分类统计产品数与价格区间、上架新品同时写产品表与定价表、产品修改后自动刷新更新时间。

华为云官方博客 478

如何使用RDS Supabase后端BaaS能力:创表即生成API(Database Data API)

认证、存储、实时推送、数据库API——4个后端模块,传统开发要数周。本系列逐个拆解,首篇聚焦数据库API(Database Data API):建表即得 API,无需手写后端。小张,AI创业公司的全栈工程师。老板让他做个产品目录页,展示产品与价格、支持上下架。传统做法要搭后端、写接口、配权限,工期少说1-2周;而在华为云RDS Supabase,建两张表、应用 SDK 直连,几分钟增删改查全跑通。

华为云官方博客 490

从一句话到一个能出去的链接,AI开发者空间做了什么

自行搭建的 Agent、正在使用的开源项目、团队既有的工具,都可以接入,可以通过AI创建或者手动搭建环境;华为云 AI开发者空间——面向开发者的云端一站式开发平台,做的就是把这段路接上:环境免安装,浏览器打开即为完整的 Linux 运行环境,预置的 AI 智能体开箱即用。第一个任务建议选能出结果的:做一个游戏、生成一个页面、创建一台实例,从需求走到可访问的链接,一次就能看清这个环境在做什么。沙箱是一个完整的 Linux 环境,依赖、服务、端口都是真实的,不是模拟。环境释放后,权限随之失效。

华为云官方博客 435

华为云码道配置自定义大模型,四种方式完整实操

案例介绍。

华为云官方博客 653

图数据库:实现穿透式监管的数据基座

穿透式监管标志着国企监管从“管企业”向“管资本”转型过程中的关键一跃。而图数据库正是这一跃的技术支点。从股权穿透到资金链穿透,从供应链穿透到数据穿透,华为GES图数据库正在将“穿透式监管”从理念变为可落地、可操作的实践。无论是天眼查式的全量链路查询,还是某集团财经的税务规则判断,抑或是芯片供应链式的部件风险分析,乃至通过Palantir构建决策知识图谱,其底层逻辑都是一致的——用图的力量,穿透一切形式的“隔离层”,直抵风险本质与责任核心。

华为云官方博客 671

《公共云三十问》正式收官,奔赴企业AI百场景新征程

今年6月底,公共云产业联盟重点推出《公共云三十问》专栏,以每周三问的节奏,连载十周,解读《先进公共云》白皮书,分享国计民生系列案例,旨在凝聚共识、推动落地实践。同时,专栏分析公共云在产业升级、民生福祉、科技创新、全球发展等方面的作用,梳理中国特色公共云发展路径:以普惠云拓展用云广度,以智算云提升用云深度,以自主云夯实用云厚度,以全球云打开用云跨度。这十问从专属云、行业云切入,深入政务、金融、交通、电力、钢铁、化工、油气、制造等国计民生场景,回答公共云“怎么用”。

华为云官方博客 476

开发者小技巧|IAM配置,让码道代码智能体连续30天免登录

案例介绍。

华为云官方博客 652

码道深度对接CodeArts,让需求自动落地为代码

案例介绍。

华为云官方博客 725

【公共云三十问 之三十】拥抱AI,企业如何建设面向智能体的专属云?

企业可分阶段建设覆盖开发、运行、运营及安全的一体化智能体平台——从构建一站式、高低码协同的智能体开发平台,到打造高性能、极致弹性的运行时环境,再到搭建AgentOps驱动的持续运营与运维体系,同时构建端到端、多层次的全链路安全防护体系。在数据湖建设方面,遵循“存量复用、平滑演进、AI导向、分步迭代”原则,分三阶段推进——打造AI多模数据湖核心能力、完成存算分离与统一元数据管理、实现闭环赋能全面支撑智能体规模化落地,在保护既有投资的前提下将传统数据平台转型为AI数据专属供给平台。

华为云官方博客 826

【公共云三十问 之二十九】国计民生之制造:制造云如何重塑数智时代的新质生产力?

平台打通软件交付的完整路径,覆盖需求管理、代码托管、代码检查、编译构建、制品仓库、部署、测试等关键环节,支持大模型能力融入研发全流程,实现从需求到交付的端到端管理。通过构建“研发一朵云”,方案打破地域与组织壁垒,实现跨团队协同开发,有效缩短软件交付周期,助力工业制造企业从“传统研发”走向“敏捷研发”,加速数智化转型进程。当制造云真正成为数据流通的平台、AI创新的底座,公共云的社会价值将从基础设施层向生产场景层持续延伸,为新型工业化建设和制造强国战略注入源源不断的动力,重塑数智时代的中国制造新质生产力。

华为云官方博客 798

告别重复手工迁仓,码道MCP+Skill实现仓库批量迁移

案例介绍。

华为云官方博客 794

【公共云三十问 之二十八】国计民生之油气:智算云如何叩响数智时代的“地心蓝金”?

西南油气田以“向地球深部要资源”为战略方向,联合以华为云Stack为代表的公共云服务商共同打造统一算力底座,建设西南区域数据湖与通用技术平台,构建“勘探开发工程技术、天然气生产过程管控、天然气产运储销”等三个一体化协同应用场景,支撑油气勘探、开发生产、管输储运等全业务链的数智化转型。当智算云真正成为数据流通的平台、AI创新的底座,油气田得以将算力效能、数据价值与智能技术深度融入勘探开发全链条,将“看不见的算力”转化为“摸得着的储量”,以智能化手段持续降低勘探风险、缩短发现周期、提高采收效率,确保生产安全。

华为云官方博客 613

【公共云三十问 之二十七】国计民生之化工:数智云如何重塑传统化工新范式?

在架构方面,方案构建云边协同的统一体系,涵盖AI协同、数据协同与运营协同三大维度——总部集中训练大模型,边缘节点负责推理执行,云边持续迭代,实现“边用边学”的智能闭环,模型平均精度提升20%以上。此外,方案提供一站式企业级工业物联网平台、数据湖与数据治理平台,覆盖工业数据分析“采、存、算、管、用”全流程,打通生产现场与管理系统间的数据壁垒,有效消除数据孤岛。层面,方案充分发挥软硬协同优势,实现计算、存储、网络与云平台的深度协同,训练线性度超95%,为大模型训练推理提供强劲算力支撑。▲化工“数智”新模式。

华为云官方博客 666

【公共云三十问 之二十六】国计民生之钢铁:数智云如何淬炼中国钢铁新力量?

同时,构建云边端协同的统一架构,支撑集团总部与各生产基地两级协同发展——总部集中训练大模型,边缘节点负责推理执行,云边持续迭代,实现训推一体化的资源调度与高效协同,为钢铁行业的数智化转型构建了坚实的算力底座。层面,方案构建覆盖“工业数采→边缘IT/OT融合→统一数据湖→数据治理平台→数据应用”全链路的一站式数据治理与流通平台,打通生产现场与管理系统间的数据壁垒,让数据“采得到、流得动、用得好”,加速数据价值从生产现场向经营决策层流动释放。湘潭钢铁集团的钢铁数智云,是钢铁工业智能云建设的标杆案例。

华为云官方博客 526

LakeWatch——MRS 智能运维Agent

从资源池、队列、作业等多个维度,对集群CPU与内存资源进行精细化分析与对比,直观呈现不同时间段的空闲、满载等使用状态,识别资源浪费,指导治理优化,为扩缩容决策提供数据支撑。对HDFS存储进行多维度深度分析(目录、用户、用户组等),涵盖使用量、增量、文件大小分布及数据热度等指标,帮助快速识别增长较快的目录、长期未访问的文件,统计目录文件数量与小文件占比,评估HDFS总存储量与扩缩容需求,为存储治理与资源规划提供全面数据支撑。Agent主动巡检,识别异常趋势并提前预警,让运维从"事后处理"转向"事前预防"。

华为云官方博客 518

华为云专题文档发布:丰富的AI案例、选型指导和概念解读

发布 “云服务选型”、“云计算概念”专题,提供云服务选型指导,助您选择匹配业务的云服务,解读云计算相关概念,开启云上学习之路。开发者工具和文档专区上线,提供从学习、实践到反馈的全链路支持。帮助中心新增100余篇AI案例。

华为云官方博客 286

一个人,也能用AI做点“星东西”

华为云星耀创想者大赛-2026华为云OPC创意大赛等你来~

华为云官方博客 293

从需求到可执行工作项:MCP+Skill 让智能体规划真正落地

回顾整个体验,以前让智能体帮我拆需求,它是洋洋洒洒给我列了一大篇 Markdown,看着挺像那么回事,但最后还是得我一条条往 CodeArts Req 里搬,搬完再手动挂父子关系、排日期,拆需求五分钟,搬运两小时。现在好了,MCP 给智能体接上了"手",Skill 给它装上了"项目经理的脑子",一句话下去,34 个工作项连带排期、层级关系全给我建好了,甘特图一拉,齐刷刷都在两周内,节省了多少工作量啊,美滋滋。本次实操在码道代码智能体基础上,构建了一套"需求→可执行工作项"的自动化规划方案。

华为云官方博客 579

华为云码道「码力续航计划」更新!

✅上新GLM‑5.3‑Flash,高速响应,代码生成、工程解析、Agent调试高效输出。新增GLM‑5.3‑Flash福利模型,每日解锁1000万免费Tokens。● 本次活动共发放总量价值100万元Tokens,发完即止!把耗算力的编码重活,交给华为云码道代码智能体🚀🚀。● 每日额度准时刷新,当日清零、次日满血重置。✅复杂算法、大项目解析、批量代码生成随便跑。✅不用抠额度、不用算消耗,放开调试大胆迭代。✅无需额外操作,登录即送,直接切换模型使用。● 把算力交给码道,让撸码不再内耗👏🏻。

华为云官方博客 698

【公共云三十问 之二十四】国计民生之交通:交通云如何铺就数智通衢新坦途?

交通行业作为支撑实体经济的关键基础设施,涵盖公路、铁路、机场、港口、地铁等众多子领域,其中,公路网络作为综合交通运输体系的基础骨架,承担着全国超过70%的客货运量,其数字化、智能化转型的需求尤为迫切。方面,提供Agent开发框架、知识库管理、RAG工程、意图识别、静态应用编排及模型评测等能力,支持客户将行业知识、业务流程与AI能力深度融合,快速构建面向收费稽核、路网调度、应急处置等场景的智能应用。开发并实现落地应用,全面覆盖建设、管理、养护、运营、服务、安全、办公七大业务领域。

华为云官方博客 466

【公共云三十问 之二十五】国计民生之电力:电力云如何点亮数智电力新引擎?

方案构建了覆盖数据获取、质量评估到标准化处理的全链路能力。基于公共云服务商智算底座及气象大模型,通过时空图神经网络重新建模产流机制,中国华电建成超50TB多源融合数据集,突破时空建模与机理融合等五大关键技术,短期径流预测精度较传统机理模型提升5个百分点以上,实现15天中期径流预测精度超85%,推理效率达秒级。基于气象大模型的基础架构与预训练能力,客户可直接在大模型之上开展增量训练与微调,充分利用场站所在区域的高精度历史数据(如3公里、1公里分辨率),针对不同场站和区域的地形地貌与气候特征进行模型调优。

华为云官方博客 382
上一篇: 基于远程开发环境部署Django与开发者空间GaussDB的实践应用
下一篇: 基于开发者空间OpenGauss数据库的分区表项目实践
华为云开发者联盟
华为云开发者联盟 企业官方账号 企业官方账号
博客等级 码龄10年 72万+粉丝 5985原创
评论
成就一亿技术人!
拼手气红包6.0元
还能输入1000个字符
 
 条评论被折叠 查看
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付:10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值