QT6.5+CMake+VS2022学习笔记

原创已于 2025-09-13 09:46:58 修改 · 475 阅读

10 ·

CC 4.0 BY-SA版权

文章标签：

#学习 #笔记

于 2025-07-22 10:13:59 首次发布

【※】Qt6.5中显示的目录结构

项目下载地址：

【免费】含资源、源码库、第三方库等的QT6.5+CMake项目资源-优快云下载

要实现下面的这种目录结构，根CMakeLists.txt定义：

cmake_minimum_required(VERSION 3.16)

# 设置项目名称
set(Project_Name ThinningMachine)
project(${Project_Name} VERSION 0.1 LANGUAGES CXX)

set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

find_package(QT NAMES Qt6 Qt5 REQUIRED COMPONENTS Widgets)
find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Widgets)

# 修改目录
set(PROJECT_SOURCES
    # 关键：添加资源文件路径，这个样子作为子模块的ui在designer中是无法找打的，但是可以用代码引用到，运行正常（奇怪）
    resources/resources.qrc
    main.cpp
    ui/mainwindow.cpp
    ui/mainwindow.h
    ui/mainwindow.ui
    ui/SwitchButton.h
    ui/SwitchButton.cpp
    ui/SwitchWidget.h
    ui/SwitchWidget.cpp
)

if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    qt_add_executable(${Project_Name}
        MANUAL_FINALIZATION
        ${PROJECT_SOURCES}

    )
    # add_executable(${Project_Name} main.cpp)
# Define target properties for Android with Qt 6 as:
#    set_property(TARGET ${Project_Name} APPEND PROPERTY QT_ANDROID_PACKAGE_SOURCE_DIR
#                 ${CMAKE_CURRENT_SOURCE_DIR}/android)
# For more information, see https://doc.qt.io/qt-6/qt-add-executable.html#target-creation
else()
    if(ANDROID)
        add_library(${Project_Name} SHARED
            ${PROJECT_SOURCES}
        )
# Define properties for Android with Qt 5 after find_package() calls as:
#    set(ANDROID_PACKAGE_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/android")
    else()
        add_executable(${Project_Name}
            ${PROJECT_SOURCES}
        )
    endif()
endif()

target_include_directories(${Project_Name} PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/ui)

# 【1】添加外部库（QT库）
target_link_libraries(${Project_Name} PRIVATE
    Qt${QT_VERSION_MAJOR}::Widgets
)

# 【2】添加外部库（源码库）
# add_subdirectory(ui)
add_subdirectory(tcpctrl)
# 使用包提供的目标
target_link_libraries(${Project_Name} PRIVATE
    # ui
    tcpctrl
)

# 【3】设置第三方库路径
set(THIRDPARTY_DIR ${CMAKE_SOURCE_DIR}/thirdparty)
# 【3.1】添加外部库（含.cmake配置第三方lib库）
# 搜索库路径的设置方法，以放在项目下thirdparty目录中为例：
list(APPEND CMAKE_PREFIX_PATH "${THIRDPARTY_DIR}/QXlsx") # 方法1：设置CMAKE_PREFIX_PATH
list(APPEND CMAKE_PREFIX_PATH "${THIRDPARTY_DIR}/spdlog") # 方法1：设置CMAKE_PREFIX_PATH
find_package(QXlsxQt${QT_VERSION_MAJOR} REQUIRED
    # PATHS "${THIRDPARTY_DIR}/QXlsx" # 方法2：直接在find_package中指定路径
)
find_package(spdlog REQUIRED
    # PATHS "${THIRDPARTY_DIR}/QXlsx" # 方法2：直接在find_package中指定路径
)
# 使用包提供的目标
target_link_libraries(${Project_Name} PRIVATE
    QXlsx::QXlsx
    spdlog::spdlog
)
#【3.2】添加外部库（不含.cmake配置第三方lib库）
# 1. 包含头文件目录
target_include_directories(${Project_Name} PRIVATE
    ${THIRDPARTY_DIR}/modbus/include/modbus  # 替换为你的头文件路径
)
# 2. 添加库文件目录
target_link_directories(${Project_Name} PRIVATE
    ${THIRDPARTY_DIR}/modbus/lib  # 替换为库文件路径
)
# 3. 链接具体库文件
target_link_libraries(${Project_Name} PRIVATE
    $<$<CONFIG:Debug>:modbusd>   # 链接 mylibd.lib (Windows) 或 libmylibd.a (Linux)
    $<$<CONFIG:Release>:modbus>  # 链接 mylib.lib 或 libmylib.a
)

# Qt for iOS sets MACOSX_BUNDLE_GUI_IDENTIFIER automatically since Qt 6.1.
# If you are developing for iOS or macOS you should consider setting an
# explicit, fixed bundle identifier manually though.
if(${QT_VERSION} VERSION_LESS 6.1.0)
  set(BUNDLE_ID_OPTION MACOSX_BUNDLE_GUI_IDENTIFIER com.example.${Project_Name})
endif()
set_target_properties(${Project_Name} PROPERTIES
    ${BUNDLE_ID_OPTION}
    MACOSX_BUNDLE_BUNDLE_VERSION ${PROJECT_VERSION}
    MACOSX_BUNDLE_SHORT_VERSION_STRING ${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}
    MACOSX_BUNDLE TRUE
    WIN32_EXECUTABLE TRUE
)

include(GNUInstallDirs)
install(TARGETS ${Project_Name}
    BUNDLE DESTINATION .
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

if(QT_VERSION_MAJOR EQUAL 6)
    qt_finalize_executable(${Project_Name})
endif()

tcpctrl下的CMakeLists.txt定义：

add_library(tcpctrl)

find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Network)
# 为了使用#include <QTextCodec>，QT6中使用QTextCodec需要在QT6安装时候选中core5compat
if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Core Core5Compat)
else()
    find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Core)
endif()

target_sources(tcpctrl
    PRIVATE
    tcpclient.h
    tcpclient.cpp
    tcpserver.h
    tcpserver.cpp
    # mysocket.h
    # mysocket.cpp
)

target_include_directories(tcpctrl
    PUBLIC
    /#表示当前目录
)

target_link_libraries(tcpctrl PRIVATE
    Qt${QT_VERSION_MAJOR}::Widgets
    Qt${QT_VERSION_MAJOR}::Network
)

if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    target_link_libraries(tcpctrl PRIVATE Qt${QT_VERSION_MAJOR}::Core Qt${QT_VERSION_MAJOR}::Core5Compat)
else()
    target_link_libraries(tcpctrl PRIVATE Qt${QT_VERSION_MAJOR}::Core)
endif()

【※】根CMakeLists.txt

# 设置项目名称
set(Project_Name ThinningMachine)

进行上面的设置后，后面就用Project_Name表示项目名，后期如果要修改项目名称很方便，QT6.5默认建立的CMake项目是没有这样的。

根CMakeLists.txt下的【1】【2】【3】分别介绍了如何如何添加QT库、源码库、第三方库（第三方库含.cmake配置、不含.cmake配置）

【※】自己的源码库abc想使用例如tcpclient库的时候，那么abc下的CMakeLists.txt要再包含tcpclient库头文件

注意要在abc里面（以abc举例）使用自己写的代码库，或者第三方的lib库，如下所示，需要在abc下的CMakeLists.txt（在根CMakeLists.txt下不管用）target_include_directories，否则包含路径写起来很麻烦

# 关键：添加 tcpctrl 目录到头文件搜索路径，可以直接#include "tcpclient.h"，避免#include "../tcpctrl/tcpclient.h"
target_include_directories(abc PRIVATE
    ${CMAKE_SOURCE_DIR}/tcpctrl  # 绝对路径更安全
)
# 关键：添加 tcpctrl 目录到头文件搜索路径，可以直接#include
target_include_directories(abc PRIVATE
    ${CMAKE_SOURCE_DIR}/thirdparty/spdlog/include  # 绝对路径更安全
)
# 关键：添加 库 目录到头文件搜索路径，可以直接#include
target_include_directories(abc PRIVATE
    ${CMAKE_SOURCE_DIR}/thirdparty/modbus/include  # 绝对路径更安全
)

同样当前abc目录同样需要，否则包含路径不好写：

target_include_directories(abc
    PUBLIC
    /#表示当前目录
)

【※】包含头文件目录注意事项

// #include <QtNetwork>//QT5.9正常，QT6.5这样用会报错
#include <QtNetwork/QTcpSocket>//QT6.5这样用才对

【※】QTextCodec

QTextCodec在QT6中已经被弃用了，如果要在QT6中使用，需要在QT6.2及以上版本安装时勾选"Qt 5 Compatibility Module"，并在CMakeLists.txt配置：

# 为了使用#include <QTextCodec>，QT6中使用QTextCodec需要在QT6安装时候选中core5compat

if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Core Core5Compat)
else()
    find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Core)
endif()

if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    target_link_libraries(tcpctrl PRIVATE Qt${QT_VERSION_MAJOR}::Core Qt${QT_VERSION_MAJOR}::Core5Compat)
else()
    target_link_libraries(tcpctrl PRIVATE Qt${QT_VERSION_MAJOR}::Core)
endif()

使用时包含头文件特别注意（被坑过，在这里一直报错）：

// #include <QTextCodec>//QT5.9正常，QT6.5这样用会报错
#include <QtCore5Compat/QTextCodec>//QT6中使用QTextCodec需要在QT安装时候选中core5compat

【※】ui窗口相关的类在根CMakeLists.txt中如何配置（事关ui引入资源文件）

如果把ui像tcpctrl一样作为库添加到项目中，有自己单独的CMakeLists.txt文件，发现如下加入资源的方式在designer设计器中是引用不到图片等资源的：

# 修改目录
set(PROJECT_SOURCES
    # 关键：添加资源文件路径，这个样子作为子模块的ui在designer中是无法找打的，但是可以用代码引用到，运行正常（奇怪）
    resources/resources.qrc
)

使用网上说的qt_add_resources方法也是不行，不知道为什么，于是只能是将ui直接加到项目根CMakeLists.txt才可以引用到，这样看到在QAction中可以引用到图片资源了：