idea database 生成bean，并且添加中文注释_ide ai 一键某个bean写注释-优快云博客

本文链接：https://blog.youkuaiyun.com/bin2277904333/article/details/82829966

本文介绍了如何在IntelliJ IDEA中通过database窗口配置数据源，选择表生成bean，并解决生成注释乱码的问题。通过实现Serializable接口、添加注释以及自定义写文件方法，确保生成的bean符合需求。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

一、调出database窗口

view---Tool windows----databse

二、添加mysql的dataSource

三、填写数据库信息，并且确定

四、选中表，去配置文件

五、添加两段代码，修改一段代码

实现Serializable接口，并且添加注释

在文件的最后添加一个方法，为了上面的代码调用

这时候如果直接生成，生成的bean注释是乱码，要再更改写文件的方法

六、修改完成的代码，可以直接复制

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.io.*
/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

packageName = "com.youxia.lookvideo.pojo;"
typeMapping = [
  (~/(?i)int/)                      : "Long",
  (~/(?i)float|double|decimal|real/): "Double",
  (~/(?i)datetime|timestamp/)       : "java.util.Date",
  (~/(?i)date/)                     : "java.util.Date",
  (~/(?i)time/)                     : "java.util.Date",
  (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
  SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
  def className = javaName(table.getName(), true)
  def fields = calcFields(table)
  PrintWriter output = new PrintWriter(new OutputStreamWriter(new FileOutputStream( new File(dir, className + ".java")), "utf-8"))
  output.withPrintWriter { out -> generate(out, className, fields) }
}

def generate(out, className, fields) {
  out.println "package $packageName"
  out.println "import java.io.Serializable;"
  out.println ""
  out.println "public class $className implements Serializable{"
  out.println ""
  fields.each() {
    if (isNotEmpty(it.commoent)) {
      out.println ""

      out.println "\t/**"
      out.println "\t * ${it.commoent}"
      out.println "\t */"
    }
    if (it.annos != "") out.println "  ${it.annos}"
    out.println "  private ${it.type} ${it.name};"
  }
  out.println ""
  fields.each() {
    out.println ""
    out.println "  public ${it.type} get${it.name.capitalize()}() {"
    out.println "    return ${it.name};"
    out.println "  }"
    out.println ""
    out.println "  public void set${it.name.capitalize()}(${it.type} ${it.name}) {"
    out.println "    this.${it.name} = ${it.name};"
    out.println "  }"
    out.println ""
  }
  out.println "}"
}

def calcFields(table) {
  DasUtil.getColumns(table).reduce([]) { fields, col ->
    def spec = Case.LOWER.apply(col.getDataType().getSpecification())
    def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
    fields += [[
                 name : javaName(col.getName(), false),
                 type : typeStr,
                 commoent: col.getComment(),
                 annos: ""]]
  }
}

def javaName(str, capitalize) {
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
    .collect { Case.LOWER.apply(it).capitalize() }
    .join("")
    .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}
def isNotEmpty(content) {
  return content != null && content.toString().trim().length() > 0
}