sap寻找用户出口方法

sap寻找用户出口方法

sap的用户出口总共有三代:

一、User EXIT
    这种出口据说是第一代的用户出口，它们include在SAP标准程序的源代码里，可以说他们是源代码的一部分，你改了这种出口就相当于改了SAP标准程序，是需要申请access key才能更改的，不需要建立PROJECT。很多标准程序里的ZZ或者Z结尾的包括程序里都有以user_exit_开始的子程序.
二、Customer exit
   可以把这种出口看成第二代的的出口，好像增强(ehancement)就是指这类，不知道我有没有理解正确，这种出口又包括了六种不同的类型.
   1）function exit,
   2)menu exit,
  3)table exit,
  4)field exit,
  5)screen exit,
  6)keyword exit，
就是function exit.这种出口是以FM的形式存在的，其开发的方式是找到相关的增强后，建立PROJECT，然后在componemt里有FM，在FM里有以Z开始INCLUDE程序,双击这个INCLUDE程序进入后就可以根据FM里IMPORT/EXPORT/CHANGING/TABLE等来开发你们的需求。这些增强是不需要申请ACCESS KEY的，因为他们不属于SAP标准程序里的一部分。这种增强FM的命名方式是EXIT_programname_NNN,NNN是3个数字的序号，实际上在SAP的标准程序里，会用到下面的方式调用该增强的逻辑：call customer-function 'NNN'，从而来达到用户的需求。

三、BADI
   这是基于面向对像的第三代增强。自己也只做过1次，特别是自己对SAP的面向对像还搞不清楚，寒~~`一时之间说不出个所以。前面介绍的两种出口增强，都是SAP提供固定的点给用户进行开发，而BADI这种增强，则让顾问们很自由地定义需要增强的地方，据说SAP很多的行业方案就是用这种形式来扩展的。
   如果你需要找某一个出口/增强，还是回去看SPRO，每一个模块里都基本有system modificatio或者BADI的说明，这样能更快找到相关的东西。

1、关于增强的简单介绍
1.1 SMOD包含具体的增强，而CMOD是包含一组SMOD编写的增强. 
1.2 User exits (Function module exits)是sap提供出口，它的命名规则如下：
EXIT_<program name><3 digit suffix> 
示例：
sd的VA01事务，对应的程序是SAPMV45A ，你会在程序里查到（用CALL CUSTOMER-FUNCTION字符串）如下代码：
CALL CUSTOMER-FUNCTION '003'
  exporting
    xvbak   = vbak
    xvbuk   = vbuk
    xkomk   = tkomk
  importing
    lvf_subrc = lvf_subrc
  tables
    xvbfa = xvbfa
    xvbap = xvbap
    xvbup = xvbup.
则exit calls function module的名称就是： EXIT_SAPMV45A_003

2、先试用SMOD建立一个SAP增强
2.1、选择一个增强，如：SDVFX001 ，点击修改，进入sap增强维护屏幕；
2.2、点击“组件”按钮，进入组件维护屏；
2.3、将光标移到“功能模块名”，输入模块名，如：EXIT_SAPLV60B_001；
2.4、选择“代码修改”按钮进入函数模块；
2.5、双击函数模块的包含单元，进入包含单元加入自定义代码并激活保存；

3、使用CMOD建立增强项目
3.1、输入自定义的项目名，点击“创建”；
3.2、进入增强项目，选择“配置增强”，进入增强配置屏幕；
3.3、输入增强名如：SDVFX001
3.4、保存，并退出；

4、使用CMOD将增强项目激活，便大工告成。

以下给出一个实例作为参考：

REPORT ZTEST_USER_EXIT  .

TABLES : TSTC,     "SAP Transaction Codes
         TADIR,    "Directory of Repository Objects
         MODSAPT,  "SAP Enhancements - Short Texts
         MODACT,   "Modifications
         TRDIR,    "System table TRDIR
         TFDIR,    "Function Module
         ENLFDIR,  "Additional Attributes for Function Modules
         TSTCT.    "Transaction Code Texts

DATA : JTAB LIKE TADIR OCCURS 0 WITH HEADER LINE.
DATA : FIELD1(30).
DATA : V_DEVCLASS LIKE TADIR-DEVCLASS.
PARAMETERS : P_TCODE LIKE TSTC-TCODE OBLIGATORY.

SELECT SINGLE * FROM TSTC WHERE TCODE EQ P_TCODE.
IF SY-SUBRC EQ 0.
  SELECT SINGLE * FROM TADIR WHERE PGMID = 'R3TR'
  AND OBJECT = 'PROG'
  AND OBJ_NAME = TSTC-PGMNA.
  MOVE : TADIR-DEVCLASS TO V_DEVCLASS.
  IF SY-SUBRC NE 0.
    SELECT SINGLE * FROM TRDIR WHERE NAME = TSTC-PGMNA.
    IF TRDIR-SUBC EQ 'F'.
      SELECT SINGLE * FROM TFDIR WHERE PNAME = TSTC-PGMNA.
      SELECT SINGLE * FROM ENLFDIR WHERE FUNCNAME =
      TFDIR-FUNCNAME.
      SELECT SINGLE * FROM TADIR WHERE PGMID = 'R3TR'
      AND OBJECT = 'FUGR'
      AND OBJ_NAME EQ ENLFDIR-AREA.

      MOVE : TADIR-DEVCLASS TO V_DEVCLASS.
    ENDIF.
  ENDIF.
  SELECT * FROM TADIR INTO TABLE JTAB
  WHERE PGMID = 'R3TR'
  AND OBJECT = 'SMOD'
  AND DEVCLASS = V_DEVCLASS.
  SELECT SINGLE * FROM TSTCT WHERE SPRSL EQ SY-LANGU AND
  TCODE EQ P_TCODE.
  FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.
  WRITE:/(19) 'Transaction Code - ',
  20(20) P_TCODE,
  45(50) TSTCT-TTEXT.
  SKIP.
  IF NOT JTAB[] IS INITIAL.
    WRITE:/(95) SY-ULINE.
    FORMAT COLOR COL_HEADING INTENSIFIED ON.
    WRITE:/1 SY-VLINE,
    2 'Exit Name',
    21 SY-VLINE ,
    22 'Description',
    95 SY-VLINE.
    WRITE:/(95) SY-ULINE.
    LOOP AT JTAB.
      SELECT SINGLE * FROM MODSAPT
      WHERE SPRSL = SY-LANGU AND
      NAME = JTAB-OBJ_NAME.
      FORMAT COLOR COL_NORMAL INTENSIFIED OFF.
      WRITE:/1 SY-VLINE,
      2 JTAB-OBJ_NAME HOTSPOT ON,
      21 SY-VLINE ,
      22 MODSAPT-MODTEXT,
      95 SY-VLINE.
    ENDLOOP.
    WRITE:/(95) SY-ULINE.
    DESCRIBE TABLE JTAB.
    SKIP.
    FORMAT COLOR COL_TOTAL INTENSIFIED ON.
    WRITE:/ 'No of Exits:' , SY-TFILL.
  ELSE.
    FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
    WRITE:/(95) 'No User Exit exists'.
  ENDIF.
ELSE.
  FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
  WRITE:/(95) 'Transaction Code Does Not Exist'.
ENDIF.

AT LINE-SELECTION.
  GET CURSOR FIELD FIELD1.
  CHECK FIELD1(4) EQ 'JTAB'.
  SET PARAMETER ID 'MON' FIELD SY-LISEL+1(10).
  CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.