EdgeUse 和 Edge的Evaluator 区别

最新推荐文章于 2024-08-26 08:21:29 发布

翻译最新推荐文章于 2024-08-26 08:21:29 发布 · 1.2k 阅读

零件专栏收录该内容

39 篇文章

订阅专栏

文章详细解释了Inventor Brep中的EdgeUse与Edge概念的区别，包括它们提供的信息类型和使用场景。通过实例代码演示了如何获取两者在不同坐标系下的坐标，有助于初学者更好地理解并应用这两个概念。

我的同事Adam最近写了篇关于EdgeUse 和 Edge的Evaluator 的区别。EdgeUse 和 Edge是初学Inventor Brep容易混淆和迷惑的知识。我认为Adam的这篇文章有一定帮助。特翻译如下。原文地址：

http://adndevblog.typepad.com/manufacturing/2013/03/evaluator-of-edgeuse-vs-edge.html

EdgeUse 提供了基于边Edge所在面Face上下文的信息。所以其Evaluator是Curve2dEvaluator ，返回的是基于面Face的信息，即返回的坐标信息是在面的参数空间内Face (u, v). 如果需要在模型空间上下文的坐标信息，则需要用Face的Evaluator 把u,v转换成模型坐标(x, y, z) 。

而Edge是基于模型空间，其Evaluator 也是Curve2dEvaluator，但返回的是模型空间坐标。

下图是个图例说明。实际中，可能0点的u,v不在面或边的起点。你需要用相应的方法先获取最小和最大值做判断。

以下代码演示了EdgeUse的Evaluator的坐标，面Face的 u,v坐标，以及模型空间坐标。先选取一个面，执行代码：

Sub PlaceParametricPoints()
    Dim oDoc As PartDocument
    Set oDoc = ThisApplication.ActiveDocument

    Dim oFace As Face
    Set oFace = oDoc.SelectSet(1)
    
    Dim oCompDef As PartComponentDefinition
    Set oCompDef = oDoc.ComponentDefinition
    
    Dim oWPs As WorkPoints
    Set oWPs = oCompDef.WorkPoints
    
    Dim oEdgeLoop As EdgeLoop
    For Each oEdgeLoop In oFace.EdgeLoops
        Dim oEdgeUse As EdgeUse
        For Each oEdgeUse In oEdgeLoop.EdgeUses
            Dim oEval As Curve2dEvaluator
            Set oEval = oEdgeUse.Evaluator
            
            ' 获取曲线参数范围 
            Dim oMinU As Double
            Dim oMaxU As Double
            Call oEval.GetParamExtents(oMinU, oMaxU)
            
            ' 获取面上参数化点
            Dim oParams(1) As Double
            Dim oFaceUV() As Double
            oParams(0) = oMinU
            oParams(1) = oMaxU
            Call oEval.GetPointAtParam(oParams, oFaceUV)
            
            ' 计算出对应模型空间点 
            Dim oModel() As Double
            Call oFace.Evaluator.GetPointAtParam(oFaceUV, oModel)
            
            Dim oTG As TransientGeometry
            Set oTG = ThisApplication.TransientGeometry
            
           ‘利用模型空间点增加一个工作点
            Call oWPs.AddFixed(oTG.CreatePoint( _
                oModel(0), oModel(1), oModel(2)))
            
            Debug.Print _
                "> Min Point >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>" + vbCrLf + _
                " Edge  u = " + str(oMinU) + vbCrLf + _
                " Face  u = " + str(oFaceUV(0)) + _
                ", v = " + str(oFaceUV(1)) + vbCrLf + _
                " Model x = " + str(oModel(0)) + _
                ", y = " + str(oModel(1)) + _
                ", z = " + str(oModel(2)) + vbCrLf + _
                "> Max Point >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>" + vbCrLf + _
                " Edge  u  = " + str(oMaxU) + vbCrLf + _
                " Face  u  = " + str(oFaceUV(2)) + _
                ", v = " + str(oFaceUV(3)) + vbCrLf + _
                " Model x = " + str(oModel(3)) + _
                ", y = " + str(oModel(4)) + _
                ", z = " + str(oModel(5))
        Next
    Next
End Sub