自制bat日志log过滤器

自制bat日志log过滤器

备注：自制日志log过滤器，采用 bat 工具，用于 windows 操作系统。根据关键字过滤出来日志内容。

@ECHO OFF

ECHO *************************  WELCOME TO LOG FILER  *****************
ECHO.
SET /p inputKey="input key words: "
ECHO.
ECHO your key words is [%inputKey%] please wait
ECHO.

SETLOCAL enabledelayedexpansion

REM 定义统一的日志结果文件名称 
set "cur_date=%DATE:~0,10%"
set "cur_date=%cur_date:/=-%" 
set "cur_time=%TIME:~0,2%_%TIME:~3,2%_%TIME:~6,2%" 
SET outFile="all_logcat_%cur_date%_%cur_time%.log"

REM 判断文件是否存在, 如果存在, 则删除之前的文件
IF EXIST %outFile%  ( DEL %outFile% )
REM 打开该文件夹下面所有的.log 或 .txt文件进行读取 
FOR %%f in (logcat.log*) do (
	REM 找到某个单独的文件当中, 所在的的每一行数据
	FOR /f "usebackq tokens=*" %%a IN ("%%f") DO (
		SET line=%%a
		REM 判断改行数据, 是否包含关键字，则写入 filter.log
		IF "!line:%inputKey%=!" NEQ "!line!" (
			ECHO %%a>>%outFile%
		)
	)
)
REM 输出结果, 通知日志已经分离完毕了
ECHO ------------------------------------------------------------------
ECHO.
ECHO SUCCESS : new log file is %outFile%
ECHO.
ECHO ------------------------------------------------------------------
PAUSE