互动媒体技术——《代码本色》习作五：粒子系统

最新推荐文章于 2022-12-05 16:05:43 发布
原创 最新推荐文章于 2022-12-05 16:05:43 发布
· 657 阅读 · 9 ·
版权
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。

1.概念介绍
2.参考案例
3.个人作品

一、概念介绍

  • 简介：粒子系统表示三维计算机图形学中模拟一些特定的模糊现象的技术，而这些现象用其它传统的渲染技术难以实现的真实感的 game physics。经常使用粒子系统模拟的现象有火、爆炸、烟、水流、火花、落叶、云、雾、雪、尘、流星尾迹或者象发光轨迹这样的抽象视觉效果等等。
  • 原理：很多细小的粒子从发射器中以一定的初速度和加速度进行向外发射。达到一定的生命周期时，会自己消失。而在整个粒子系统中，还有很多新的粒子会不断地产生。

二、参考案例

1.案例一：受力作用的粒子系统
  • 简介
    应用运动遵循牛顿第二定律原则F=M*A，同时将力的累加算法作用在粒子上，实现更好的模拟框架
  • 实现步骤
    1.建立单个粒子类：初始化粒子速度，加速度，绘制粒子，更新位置
    2.建立粒子系统类：初始化粒子系统，添加力，绘制粒子系统。
    3.实现添加力的函数（思想是将力作用在粒子系统上，系统再将力作用在每个粒子上）
  • 代码展示
import java.util.Iterator;
//粒子系统
ParticleSystem ps;
//排斥对象
//Repeller repeller;
void setup() {
  size(400,400);
  smooth();
  ps=new ParticleSystem(new PVector(width/2,50));
}
void draw(){
  background(0);
  PVector gravity =new PVector(0,0.1);
  ps.applyForce(gravity);
  ps.addParticles();
  ps.run();
}
//*******************************粒子系统类******************************
class ParticleSystem {
  ArrayList<Particle>particles;
  PVector origin;//粒子发射的起点
  //构造函数
  ParticleSystem(PVector location){
    origin=location.get();
    particles=new ArrayList<Particle>();
  }
  //添加粒子
  void addParticles(){
    particles.add(new Particle(origin));
  }
  //增加力:这里是通过把力作用在粒子系统上，再通过粒子系统把力作用在所有的粒子上实现的
  void applyForce(PVector f){
    for(Particle p:particles){
       p.applyForce(f);
    }
  }
  //绘制粒子系统
  //注意：再这里不能使用改进型的for循环，因为要在遍历过程中删除元素
  void run(){
    //迭代器
    Iterator<Particle> it =particles.iterator();
    while(it.hasNext()){
      Particle p=(Particle)it.next();
      p.run();
      if(p.isDead()){
        it.remove();      
      }
    }
  }
}
//************************************粒子类*****************************
class Particle {
  PVector location;//位置
  PVector velocity;//速度
  PVector acceleration;//加速度
  float lifespan;//生命周期
  float mass=1;//改变加速度
  //构造函数
  Particle(PVector L) {
    acceleration =new PVector(0, 0);//初始加速度从0开始
    velocity=new PVector(random(-1, 1), random(-2, 0));
    location=L.get();
    lifespan=255.0;
  }
  void run() {
    update();
    display();
  }
  //添加力
  void applyForce(PVector force) {
    PVector f =force.get();//先取出，否则会对内部进行修改
    f.div(mass);
    acceleration.add(f);
  }
  //更新粒子的位置
  void update() {
    velocity.add(acceleration);
    location.add(velocity);
    acceleration.mult(0);
    lifespan-=2.0;
  }
  //绘制粒子
  void display() {
    stroke(255, lifespan);
    fill(255, lifespan);
    ellipse(location.x, location.y, 8, 8);
  }
  boolean isDead() {
    if (lifespan< 0.0){
      return true;
    }else{
      return false;
    }
  }
}
  • 效果展示
    在这里插入图片描述
2.案例二：不同粒子的粒子系统
  • 简介
    在同一个发射器中，发射出不同的粒子，有各种形状，不同大小，不同颜色。
  • 思路
    用多态实现粒子系统。使得新的粒子继承原始粒子，重新display（绘制粒子）的函数，最后通过父类引用指向子类对象进行函数的调用。力的作用和使用到的公式同上一个案例
    在这里插入图片描述
  • 拓展
    原始案例中没有对每一个粒子的大小形状做出改变。在这里可以使用random函数随机生成粒子的大小和形状。同时将一个粒子系统拓展为多个粒子系统。粒子系统的位置也随机指定。同时加入鼠标的交互，点击鼠标时，改变粒子系统的位置。
  • 代码展示
import java.util.Iterator;
//粒子系统
ParticleSystem[] ps=new ParticleSystem[5];
void setup() {
  size(800, 400);
  smooth();
  for (int i=0; i<5; i++) {
    ps[i]=new ParticleSystem(new PVector(random(100, width), random(0, 200)));
  }
}
void draw() {
  background(0);
  PVector gravity =new PVector(0, 0.1);
  for (int i=0; i<5; i++) {
    ps[i].applyForce(gravity);
    ps[i].addParticles();
    ps[i].run();
  }
}

void mouseClicked(){
   for (int i=0; i<5; i++) {
    ps[i]=new ParticleSystem(new PVector(random(100, width), random(0, 200)));
  }
}
//************************************粒子类*****************************
class Particle {
  PVector location;//位置
  PVector velocity;//速度
  PVector acceleration;//加速度
  float lifespan;//生命周期
  float mass=1;//改变加速度
  //构造函数
  Particle(PVector L) {
    acceleration =new PVector(0, 0);//初始加速度从0开始
    velocity=new PVector(random(-1, 1), random(-2, 0));
    location=L.get();
    lifespan=255.0;
  }
  void run() {
    update();
    display();
  }
  //添加力
  void applyForce(PVector force) {
    PVector f =force.get();//先取出，否则会对内部进行修改
    f.div(mass);
    acceleration.add(f);
  }
  //更新粒子的位置
  void update() {
    velocity.add(acceleration);
    location.add(velocity);
    acceleration.mult(0);
    lifespan-=2.0;
  }
  //绘制粒子
  void display() {
    stroke(random(125, 255), random(215, 255), random(0, 255), lifespan);
    fill(random(0, 255), random(0, 255), random(0, 255), lifespan);
    ellipse(location.x, location.y, random(0.5, 15), random(0.5, 15));
  }
  boolean isDead() {
    if (lifespan< 0.0) {
      return true;
    } else {
      return false;
    }
  }
}
//创建粒子类的子类
class Confetti extends Particle {
  Confetti(PVector L) {
    super(L);
  }
  //覆盖display方法
  void display() {
    float theta=map(location.x, 0, width, 0, TWO_PI*2);
    rectMode(CENTER);
    fill(random(0, 255), random(0, 255), random(0, 255), lifespan);
    stroke(random(0, 255), random(0, 255), random(0, 255), lifespan);
    rect(location.x, location.y, random(0.5, 15), random(0.5, 15));
  }
}
//*******************************粒子系统类******************************
class ParticleSystem {
  ArrayList<Particle>particles;
  PVector origin;//粒子发射的起点
  //构造函数
  ParticleSystem(PVector location) {
    origin=location.get();
    particles=new ArrayList<Particle>();
  }
  //添加粒子
  void addParticles() {
    float r=random(1);
    if (r<0.5) {
      particles.add(new Particle(origin));
    } else {
      particles.add(new Confetti(origin));
    }
  }
  //增加力:这里是通过把力作用在粒子系统上，再通过粒子系统把力作用在所有的粒子上实现的
  void applyForce(PVector f) {
    for (Particle p : particles) {
      p.applyForce(f);
    }
  }
  //绘制粒子系统
  //注意：再这里不能使用改进型的for循环，因为要在遍历过程中删除元素
  void run() {
    //迭代器
    Iterator<Particle> it =particles.iterator();
    while (it.hasNext()) {
      Particle p=it.next();
      p.run();
      if (p.isDead()) {
        it.remove();
      }
    }
  }
}
  • 效果展示
    在这里插入图片描述
    在这里插入图片描述

三、个人作品

作品一：飞舞的泡泡
  • 简介
    该作品用利用图像纹理来模拟泡泡在空中的飘动，同时也模拟火焰的效果。可以在两种效果之间进行切换
  • 步骤
    1.导入图片：使用Pimage
    2.为泡泡的漂浮设计规则：泡泡受到重力，浮力，空气阻力。但是整体有一个向上升的趋势。因此浮力大于空气阻力加重力。而在这里为了简化，可以把三个力合成为一个力，通过添加到粒子系统上进而添加给粒子系统中的每一个粒子。同时，泡泡也会收到风力的作用，而这里为了实现交互的话，将风力的方向与鼠标的位置关联在一起，可以实现鼠标所在之处，为泡泡所漂浮的方向。
    重力：F=m*g
    浮力：F浮=ρgV
    阻力：f=umg
    在这里插入图片描述
    3.为火焰设计规则：火焰的话在泡泡的基础上减少一个空气阻力
  • 类的设计
    在这里插入图片描述
  • 代码展示
//图像纹理
PImage img;
import java.util.Iterator;
//粒子系统
ParticleSystem ps;
boolean flag=false;
void setup() {
  size(800, 400);
  smooth();
  ps=new ParticleSystem(new PVector(width/2, height));
  img=loadImage("pao2.png");
}
void draw() {
  background(0);
  float dx=map(mouseX, 0, width, -0.2, 0.2);
  PVector wind=new PVector(dx, 0);
  PVector buoyancy=new PVector(0, random(-0.2, 0.2));
  if(!flag)ps.applyForce(buoyancy);
  ps.applyForce(wind);
  ps.run();
  ps.addParticles();
}
void mouseClicked() {
  if (!flag) {
    flag=true;
    img=loadImage("fire5.png");
  } else {
    img=loadImage("pao2.png");
    flag=false;
  }
}
//*******************************粒子系统类******************************
class ParticleSystem {
  ArrayList<Particle>particles;
  PVector origin;//粒子发射的起点
  //构造函数
  ParticleSystem(PVector location) {
    origin=location.get();
    particles=new ArrayList<Particle>();
  }
  //添加粒子
  void addParticles() {
    particles.add(new Particle(origin));
  }
  //增加力:这里是通过把力作用在粒子系统上，再通过粒子系统把力作用在所有的粒子上实现的
  void applyForce(PVector f) {
    for (Particle p : particles) {
      p.applyForce(f);
    }
  }
  //绘制粒子系统
  //注意：再这里不能使用改进型的for循环，因为要在遍历过程中删除元素
  void run() {
    //迭代器
    Iterator<Particle> it =particles.iterator();
    while (it.hasNext()) {
      Particle p=(Particle)it.next();
      p.run();
      if (p.isDead()) {
        it.remove();
      }
    }
  }
}
//************************************粒子类*****************************
class Particle {
  PVector location;//位置
  PVector velocity;//速度
  PVector acceleration;//加速度
  float lifespan;//生命周期
  float mass=1;//改变加速度
  //构造函数
  Particle(PVector L) {
    acceleration =new PVector(0, 0);//初始加速度从0开始
    velocity=new PVector(random(-1, 1), random(-8, 0));
    location=L.get();
    lifespan=255.0;
  }
  void run() {
    update();
    display();
  }
  //添加力
  void applyForce(PVector force) {
    PVector f =force.get();//先取出，否则会对内部进行修改
    f.div(mass);
    acceleration.add(f);
  }
  //更新粒子的位置
  void update() {
    velocity.add(acceleration);
    location.add(velocity);
    acceleration.mult(0);
    lifespan-=2.0;
  }
  //绘制粒子
  void display() {
    //stroke(255, lifespan);
    //fill(255, lifespan);
    //ellipse(location.x, location.y, 8, 8);
    render();
  }
  void render() {
    imageMode(CENTER);
    tint(255, lifespan);
    image(img, location.x, location.y);
  }
  boolean isDead() {
    if (lifespan< 0.0) {
      return true;
    } else {
      return false;
    }
  }
}
  • 效果展示
    在这里插入图片描述
作品二：破碎的人像
  • 简介
    鼠标互动可以切换图片，点击鼠标后所有的小方格将会破碎，并因重力作用而向下坠落。单个粒子是由rect构成，rect的参数由粒子系统进行传递，传递的是rgb的值，单个粒子的大小可以根据实际进行调整：如果希望看起来像马赛克效果，可以增加rect的大小，这里我将rect的大小设置为了1
  • 效果展示
    在这里插入图片描述
  • 代码展示（核心）
ParticleSystem ps;
PImage photo;
int index=1;//当前的图片序号
String pic[]={"heben.jpg","heben1.jpg","heben2.jpg","heben3.jpg"};
void setup() { 
  size(200, 200);
  photo = loadImage("heben.jpg");
  photo.loadPixels();
  ps = new ParticleSystem(0, 0, 1, photo);
}

void draw() {
  background(0);   
  ps.display();
  ps.update();
} 
void mouseClicked() {
  ps.shatter();
}  
void mouseWheel(){
  if(index==4){
    index=0;
  }
  photo = loadImage(pic[index]);
  photo.loadPixels();  
  ps = new ParticleSystem(0, 0, 1, photo);
  index++;
  
}
C语言2700行代码，粒子系统 (Particle System) ，EasyX图形库最强代码~
C语言C++学习俱乐部：765860056
12-19 897
粒子系统的一个普遍公认的定义是：粒子系统由具有相同属性规则的微小个体组成，大量微小个体可以随机显示不同特征的粒子的集合体。
【互动编程作业】粒子系统——粒子系统的实现
A_Ainley的博客
12-10 815
前言 在《代码本色》的第4章 粒子系统 中，主要讲到了粒子系统的实现、多态和继承实现面向对象以及通过力的作用体现自然系统。以下为第4章的内容目录： 针对粒子系统的实现、多态和继承实现面向对象以及通过力的作用体现自然系统，我展开了自己的习作。 关于习作 学习了《代码本色》第4章 粒子系统 的内容之后，我想要在我的习作中表现的元素有： 鼠标的交互 粒子系统的生成 随机点的生成 排斥力的体现 其中...
粒子系统代码示例
boring
10-26 836
在书上看到的粒子系统的示例分享给大家参考，希望可以帮助大家学习安卓！   首先是MyRenderer.java   package com.boring.ParticleActivity; import java.nio.ByteBuffer; import java.nio.ByteOrder; import java.nio.FloatBuffer; import j...
OpenGL ES2.0粒子系统(附有源码)
cxy200927099的专栏
08-15 3308
刚学OpenGL 2个多星期，也算是入门了吧 在看了老外写的书 OpenGL ES 2 for Android A Quick - Start Guide.pdf 后，由于这本书上给的代码不够全，自己功力太浅，对于一些了解有点疑惑， 费了差不多两天才调出想要的结果，下面就分享一下我的经历，若有问题，希望大家多多交流 本代码中包含的内容还是比较多的，使用OpenG
Irrlicht实现粒子系统（演示程序+源代码）
11-26
粒子系统是作为游戏引擎不可或缺的一部分，它可以创造出非常炫的效果，但是传统上，如果是从Direct3D或者是从OpenGL/GLUT开始，将会遇到很大的麻烦，因为需要定义粒子发射器以及粒子管理器，还有种种复杂的东西，以前我曾经用Direct3D模仿粒子系统制作弹幕，就知道管理粒子有多么的复杂。不过在使用了Irrlicht之后，我觉得使用粒子系统简单了许多，只需要调用几个函数就可以解决问题。
互动媒体技术——代码本色学习及拓展
Arzeus的博客
01-04 312
概述 参考《代码本色》的第0~4章内容及其实例程序（自行在processing内下载），针对这5章分别编写1个习作（一共5个），每个习作都有不少于2个案例参考，且必须有一定的拓展； 选择工具：Processing 3.0.1 第0章 引言 参考示例： 0-3 有右移趋势的Walker对象 0-5 Perlin噪声游走模型 效果展示： 拓展方向： 学习了第0章之后，选择以示例0-3为基础，制作一个...
代码本色——雪梨的Processing探索·Chapter 4：粒子系统
FShirley的博客
01-07 1714
概述 Chapter 4为我们介绍了粒子系统的相关概念，让我们更加了解了仿真于自然系统的变化是如何产生的，更引入了继承与多态的思想，让我们对于粒子系统的创造力赞叹不已，让我们先来了解下这些原理，然后再让我们来发挥想象进行这些知识的运用创作。 原理介绍 粒子系统 ...
《代码本色案例》：深入探索Processing与Java粒子模拟
在编程中，粒子系统是通过定义粒子类和相关的物理属性（如位置、速度、加速度）来实现的，而粒子之间的交互规则（如排斥、吸引、随机扩散等）通常会通过代码来设定。这些代码本色案例不仅揭示了自然规律在编程中的...
processing编程习作：《代码本色》chp0-4（互动媒体技术作业）
weixin_44123437的博客
12-14 1655
processing编程习作：《代码本色》chp0-4（互动媒体技术作业）习作1：引言（chp0）展示代码&分析习作2：向量（chp1）展示代码&分析习作3：力（chp2）展示代码&分析习作4：振荡（chp3）展示代码＆分析习作5：粒子系统（chp4）展示代码&分析 习作1：引言（chp0） 展示 本习作是对Perlin噪声的拓展应用，通过控制噪声随时间的平滑变化...
FISH&FOOD——代码本色
qq_40301536的博客
05-06 961
目录游戏内容1.开始界面2.过度场景3.游戏场景功能快捷键合理的创建标题，有助于目录的生成如何改变文本的样式插入链接与图片如何插入一段漂亮的代码片生成一个适合你的列表创建一个表格设定内容居中、居左、居右SmartyPants创建一个自定义列表如何创建一个注脚注释也是必不可少的KaTeX数学公式新的甘特图功能，丰富你的文章UML 图表FLowchart流程图导出与导入导出导入 每次到了做作业的时候，...
实现粒子系统
06-18
OpenGL实现粒子系统的多种基础操作，菜单交互实现等
Nehe第19课粒子系统源代码20121007
10-07
Nehe第19课粒子系统20121007源代码，资源
简单的粒子系统实现
04-14
一个简单的win32 粒子系统
键盘交互示例程序
12-29
一个教会你如何用键盘传递给程序信息的示例程序。。。
粒子系统简单框架实现
05-03
粒子系统的一个简单框架 class CParticleSystem; class CParticle { public: enum TYPE { VISTUAL, PARTICLE_SYSTEM }; public: CParticle(VOID); virtual ~CParticle(VOID); public: INT liveFrame; // 生存时间 INT indexFrame; // 贞索引 BOOL isKeepLocal; // 保持本地坐标 // 说明: 相对于发射他的发射器而言 VEC3 scale; // 缩放 VEC3 position; // 位置 QUAT orientation; // 朝向 VEC4 color; // 颜色 VEC2 uvOffset; // 纹理坐标偏移 VEC3 velocity; // 速度 public: CParticle *pNext; // 链接下一个粒子 public: CEmitterBase *pEmitter; // 发射器指针 CParticleSystem *pEmitParticleSystem; // 发射的粒子系统 }; class CParticleSystem { public: typedef std::vector EmitterSet; typedef std::vector AffectorSet; public: CParticleSystem(VOID); virtual ~CParticleSystem(VOID); public: VOID SetParticleQuota(INT quota, CParticle::TYPE type, const CHAR *szParticleSystem); // 设置粒子总量 INT GetParticleQuota(VOID) const; // 获得粒子总量 public: VOID SetGfx(CGfxBase::TYPE type); // 设置图形 CGfxBase* GetGfx(VOID) const; // 获得图形 public: CEmitterBase* AddEmitter(CEmitterBase::TYPE type); // 添加发射器 VOID RemoveEmitter(CEmitterBase *pEmitte
粒子系统
princebear123的博客
11-09 787
粒子系统简单粒子制作1.1、粒子制作 简单粒子制作 按参考资源要求，制作一个粒子系统，参考资源 使用 3.3 节介绍，用代码控制使之在不同场景下效果不一样 1.1、粒子制作 本次作业是有光晕和星光这两种Particle System。 ...
3D游戏编程与设计作业——粒子系统
Xiaozhen__的博客
12-05 219
3D游戏编程与设计作业——粒子系统
粒子系统实现与原理
微小的鱼的博客
09-30 5049
先简单讲述粒子的基本概念，包括分类等等，结合本人做过，在公司实现的粒子系统的思路、总结等等，包括未来也是比较新的粒子系统实现方式，根据需求制作一个粒子系统。
评论 2
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值