U盘病毒查杀并打补丁

一个查杀U盘病毒并给每个磁盘打补丁的批处理，打过补丁后的磁盘（包括U盘、移动硬盘）可以避免感染绝大部分U盘病毒。下面给出程序代码：
@echo off
cls
color 0D
echo.
echo    ***************************************************************
echo    *                                                             *
echo    *                 欢迎使用U盘病毒查杀工具！                   *
echo    *              本程序将扫描所有磁盘和系统目录                 *
echo    *                 杀除所有U盘病毒并给出提示                   *
echo    *                                                             *
echo    *                                                             *
echo    *                             制作者:shadow                   *
echo    *                                                             *
echo    ***************************************************************
echo.
echo.
echo.
echo 任意键开始扫描…
pause>nul
cls
echo.
if not exist C:/MOVED (
    mkdir C:/MOVED
    attrib +r +h +s C:/MOVED
)
set killed=NO
set unkill=NO
for %%X in (A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z) do (
    if exist %%X: (
        echo.
        echo Messege:正在扫描%%X盘…
        echo.>%%X:/XXX
        if not exist %%X:/XXX (
            echo Warning:%%X盘受保护，程序忽略!
        ) else (
            del %%X:/XXX 2>nul
            cd %%X:/autorun.inf 2>nul
            if errorlevel 1 (
                if exist %%X:/autorun.inf (
                    echo Messege:%%X盘发现可疑情况
                    for /f "eol=[ tokens=2 delims== " %%F in (%%X:/autorun.inf) do (
                        taskkill /F /IM %%F>nul 2>nul
                        for %%P in (%%X:,%%systemroot%%,%%systemroot%%/SYSTEM32,%%systemroot%%/SYSTEM) do (
                            if exist %%P/%%F (
                                attrib -r -h -s %%P/%%F                            
                                move %%P/%%F C:/MOVED/%date:~0,10%_%time:~0,2%-%time:~3,2%-%time:~6,2%_%%X_%%F
                                if errorlevel 1 (
                                    set unkill=YES
                                    echo Error  :无法处理可疑文件%%P/%%F!
                                ) else (
                                    set killed=YES
                                    echo %date% %time%     %%P/%%F>>C:/MOVED/RECORD.TXT                              
                                    echo Messege:成功处理可疑文件%%P/%%F
                                )
                            )
                        )                        
                    )
                    attrib -r -h -s %%X:/autorun.inf
                    move %%X:/autorun.inf C:/MOVED/%date:~0,10%_%time:~0,2%-%time:~3,2%-%time:~6,2%_%%X_autorun.inf
                    if errorlevel 1 (
                        set unkill=YES
                        echo Error  :无法处理可疑文件%%X:/autorun.inf!
                    ) else (
                        set killed=YES
                        echo %date% %time%     %%X:/autorun.inf>>C:/MOVED/RECORD.TXT
                        echo Messege:成功处理可疑文件%%X:/autorun.inf
                    )
                )
                mkdir %%X:/autorun.inf
                echo [.ShellClassInfo]>%%X:/autorun.inf/Desktop.ini
                echo IconIndex=^0>>%%X:/autorun.inf/Desktop.ini
                echo IconFile=%%systemroot%%/system32/cleanmgr.exe>>%%X:/autorun.inf/Desktop.ini
                echo InfoTip=U盘病毒补丁——Shadow制作>>%%X:/autorun.inf/Desktop.ini
                mkdir %%X:/autorun.inf/xXx
                attrib +r +h +s %%X:/autorun.inf/xXx
                attrib +r +h +s %%X:/autorun.inf/Desktop.ini
                attrib +r +h +s %%X:/autorun.inf
                echo Messege:%%X盘成功免疫!
            ) else echo Messege:%%X盘文件安全!            
        )
    )
)
echo.
echo.
echo Messege:扫描结束
if "%unkill%"=="YES" (
    color 0C
    echo Warning:发现可疑情况但无法彻底解决!
) else (
    if "%killed%"=="YES" (
        color 0A
        echo Messege:发现可疑情况并成功解决!
    ) else (
        echo Messege:没有发现任何可疑情况
    )
)
echo.
echo 任意键继续…
pause>nul
cls
color 0D
echo.
echo    ***************************************************************
echo    *                                                             *
echo    *                     版权没有，随意修改                      *
echo    *                    感谢您的任何宝贵意见                     *
echo    *                  xiaoyuhan.programfan.com                   *
echo    *                         谢谢使用!                           *
echo    *                                                             *
echo    ***************************************************************
echo.
echo.
echo.
echo 任意键退出…
pause>nul
if "%killed%"=="YES" (
    taskkill /F /IM explorer.exe>nul 2>nul
    start /D%%systemroot%% /MIN /B %%systemroot%%/explorer.exe
    start /Dc:/progra~1/intern~1 /MAX c:/progra~1/intern~1/iexplore.exe
)
echo on