show_space procedure ---Thomas Kyte

show_space procedure

在拜读Thomas Kyte 的oracle编程艺术时，看到Thomas Kyte 开发了一些灰常实用的过程和包。记录一下，方便使用.

show_space：用于打印数据库段的空间利用率。接口如下

SQL> desc show_space
PROCEDURE show_space
 Argument Name                  Type                    In/Out Default?
 ------------------------------ ----------------------- ------ --------
 P_SEGNAME                      VARCHAR2                IN
 P_OWNER                          VARCHAR2                IN     DEFAULT
 P_TYPE                               VARCHAR2                IN     DEFAULT
 P_PARTITION                     VARCHAR2                IN     DEFAULT

P_SEGNAME ：段名

P_OWNER ：默认为当用户，不过可以指定来查看其它模式下的。

P_TYPE ：默认为 TABLE ,用户查看的段的类型。

P_PARITION ：显示分区对象的空间时所用的分区名。show_space一次只显示一个分区的空间利用率。

创建 show_space过程

create or replace procedure show_space
( p_segname in varchar2,
  p_owner   in varchar2 default user,
  p_type    in varchar2 default 'TABLE',
  p_partition in varchar2 default NULL )
-- this procedure uses authid current user so it can query DBA_*
-- views using privileges from a ROLE and so it can be installed
-- once per database, instead of once per user that wanted to use it
authid current_user
as
    l_free_blks                 number;
    l_total_blocks              number;
    l_total_bytes               number;
    l_unused_blocks             number;
    l_unused_bytes              number;
    l_LastUsedExtFileId         number;
    l_LastUsedExtBlockId        number;
    l_LAST_USED_BLOCK           number;
    l_segment_space_mgmt        varchar2(255);
    l_unformatted_blocks number;
    l_unformatted_bytes number;
    l_fs1_blocks number; l_fs1_bytes number;
    l_fs2_blocks number; l_fs2_bytes number;
    l_fs3_blocks number; l_fs3_bytes number;
    l_fs4_blocks number; l_fs4_bytes number;
    l_full_blocks number; l_full_bytes number;

        -- inline procedure to print out numbers nicely formatted
        -- with a simple label
    procedure p( p_label in varchar2, p_num in number )
    is
    begin
        dbms_output.put_line( rpad(p_label,40,'.') ||
                              to_char(p_num,'999,999,999,999') );
    end;
begin
   -- this query is executed dynamically in order to allow this procedure
   -- to be created by a user who has access to DBA_SEGMENTS/TABLESPACES
   -- via a role as is customary.
   -- NOTE: at runtime, the invoker MUST have access to these two
   -- views!
   -- this query determines if the object is a ASSM object or not
   begin
      execute immediate
          'select ts.segment_space_management
             from dba_segments seg, dba_tablespaces ts
            where seg.segment_name      = :p_segname
              and (:p_partition is null or
                  seg.partition_name = :p_partition)
              and seg.owner = :p_owner
              and seg.tablespace_name = ts.tablespace_name'
             into l_segment_space_mgmt
            using p_segname, p_partition, p_partition, p_owner;
   exception
       when too_many_rows then
          dbms_output.put_line
          ( 'This must be a partitioned table, use p_partition => ');
          return;
   end;


   -- if the object is in an ASSM tablespace, we must use this API
   -- call to get space information, else we use the FREE_BLOCKS
   -- API for the user managed segments
   if l_segment_space_mgmt = 'AUTO'
   then
     dbms_space.space_usage
     ( p_owner, p_segname, p_type, l_unformatted_blocks,
       l_unformatted_bytes, l_fs1_blocks, l_fs1_bytes,
       l_fs2_blocks, l_fs2_bytes, l_fs3_blocks, l_fs3_bytes,
       l_fs4_blocks, l_fs4_bytes, l_full_blocks, l_full_bytes, p_partition);

     p( 'Unformatted Blocks ', l_unformatted_blocks );
     p( 'FS1 Blocks (0-25)  ', l_fs1_blocks );
     p( 'FS2 Blocks (25-50) ', l_fs2_blocks );
     p( 'FS3 Blocks (50-75) ', l_fs3_blocks );
     p( 'FS4 Blocks (75-100)', l_fs4_blocks );
     p( 'Full Blocks        ', l_full_blocks );
  else
     dbms_space.free_blocks(
       segment_owner     => p_owner,
       segment_name      => p_segname,
       segment_type      => p_type,
       freelist_group_id => 0,
       free_blks         => l_free_blks);

     p( 'Free Blocks', l_free_blks );
  end if;

  -- and then the unused space API call to get the rest of the
  -- information
  dbms_space.unused_space
  ( segment_owner     => p_owner,
    segment_name      => p_segname,
    segment_type      => p_type,
    partition_name    => p_partition,
    total_blocks      => l_total_blocks,
    total_bytes       => l_total_bytes,
    unused_blocks     => l_unused_blocks,
    unused_bytes      => l_unused_bytes,
    LAST_USED_EXTENT_FILE_ID => l_LastUsedExtFileId,
    LAST_USED_EXTENT_BLOCK_ID => l_LastUsedExtBlockId,
    LAST_USED_BLOCK => l_LAST_USED_BLOCK );

    p( 'Total Blocks', l_total_blocks );
    p( 'Total Bytes', l_total_bytes );
    p( 'Total MBytes', trunc(l_total_bytes/1024/1024) );
    p( 'Unused Blocks', l_unused_blocks );
    p( 'Unused Bytes', l_unused_bytes );
    p( 'Last Used Ext FileId', l_LastUsedExtFileId );
    p( 'Last Used Ext BlockId', l_LastUsedExtBlockId );
    p( 'Last Used Block', l_LAST_USED_BLOCK );
end;
/

使用show_space查看段利用率 (ASSM表空间下的TEST_E 表)

SQL> exec show_space('TEST_E');
Unformatted Blocks .....................               0
FS1 Blocks (0-25)  .....................               0
FS2 Blocks (25-50) .....................               0
FS3 Blocks (50-75) .....................               0
FS4 Blocks (75-100).....................               7
Full Blocks        .....................           3,219
Total Blocks............................           3,296
Total Bytes.............................      27,000,832
Total MBytes............................              25
Unused Blocks...........................               0
Unused Bytes............................               0
Last Used Ext FileId....................               4
Last Used Ext BlockId...................           3,840
Last Used Block.........................             104

PL/SQL procedure successfully completed.

Elapsed: 00:00:00.05

--报告中的各项结果：

Unformatted Blocks：为表分配的位于高水位线之下但是未用的块数。把未格式化和已格式化但是未使用的块加一起。就是已为表分配但从未用于保存的ASSM对象数据的总块

FS1 Blocks~FS4 Blocks：包含数据的格式化块。项名后的数字表示各块的“空闲度‘，例如（0~25）是指空闲度为0~25%的块数。

Full Blocks：已满的块数，不能再向这些块插入数据。

Total Blocks、Total Bytes、Total MBytes：为所查看的段分配的总空间量。单位分别是数据库块，字节，M。

Unused Blocks、Unused Bytes：表示未用空间所占的比例。这些块已经分配给所查看的段。但目前位于高水位线之上。

Last Used Ext FileId：包含最后一个块（其中包含数据）的文件的文件ID

Last Used Ext BlockId：最后一个区段开始处的块ID,这是最后使用的文件中的块的ID.也就是Last Used Ext FileId  ID号中的块ID.

Last Used Block：最后区段中，最后一个块的偏移量。

对象在用户管理的表空间中，使用show_space输出如下：（TEST_B 位于用户管理的表空间）

SQL> exec show_space('TEST_B');
Free Blocks.............................               2
Total Blocks............................           3,328
Total Bytes.............................      27,262,976
Total MBytes............................              26
Unused Blocks...........................             118
Unused Bytes............................         966,656
Last Used Ext FileId....................               1
Last Used Ext BlockId...................          99,456
Last Used Block.........................              10

PL/SQL procedure successfully completed.

Elapsed: 00:00:00.03

唯一区别是Free Blocks ，这是段的第一个free_list（自由列表）组中的块数。本脚本只测试了第一个free_list组。