flex tree 自动显示横向滚动条

最新推荐文章于 2024-09-24 18:46:25 发布

转载最新推荐文章于 2024-09-24 18:46:25 发布 · 923 阅读

FLEX 专栏收录该内容

1 篇文章

订阅专栏

本文介绍了一个名为AutoSizeTree的自定义Tree组件，它能够自动显示横向滚动条，通过调整滚动策略和更新显示列表来实现在不同宽度下自适应显示。此组件适用于需要在有限空间内展示大量数据的场景。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

package com.anydata.consumer.components
{
 import flash.events.Event;
 import mx.controls.Tree;
 import mx.core.ScrollPolicy;
 import mx.core.mx_internal;

 /**
 * 自动显示横向滚动条
 */
 public class AutoSizeTree extends Tree
 {
  public function AutoSizeTree()
  {
   super();
   horizontalScrollPolicy=ScrollPolicy.AUTO;
  }

  override public function get maxHorizontalScrollPosition():Number
  {
   if (isNaN(mx_internal::_maxHorizontalScrollPosition))
    return 0;
   return mx_internal::_maxHorizontalScrollPosition;
  }

  override public function set maxHorizontalScrollPosition(value:Number):void
  {
   mx_internal::_maxHorizontalScrollPosition=value;
   dispatchEvent(new Event("maxHorizontalScrollPositionChanged"));
   scrollAreaChanged=true;
   invalidateDisplayList();
  }

  override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
  {
   var diffWidth:Number=measureWidthOfItems(0, 0) - (unscaledWidth - viewMetrics.left - viewMetrics.right);

   var indentation:Number=getStyle("indentation");

   if (diffWidth <= 0)
    maxHorizontalScrollPosition=NaN;
   else
    maxHorizontalScrollPosition=diffWidth + indentation;
   super.updateDisplayList(unscaledWidth, unscaledHeight);
  }
 }
}