批处理删除指定天数日期之前的文件(2017-05-17)

 

【方案1】以文件的最后修改时间为准 BAT + PowerShell
 
  1. @echo off
  2. REM ------------------------------------------------------------------------------
  3. REM 如果显示的待删除文件列表正确无误
  4. REM 把 Select-Object FullName 修改成 Remove-Item -Force 再次执行即可真正删除文件
  5. REM Win7/Win8/Win10等系统自带PowerShell
  6. REM ------------------------------------------------------------------------------
  7.  
  8. REM 指定待删除文件的存放路径
  9. set SrcDir=C:\Test\BatHome
  10. REM 指定天数
  11. set DaysAgo=10
  12.  
  13. powershell -c "Get-ChildItem -Path '%SrcDir%' -Recurse -ErrorAction:SilentlyContinue | Where-Object -FilterScript {(((get-date) - ($_.LastWriteTime)).days -gt %DaysAgo% -and $_.PsISContainer -ne $True)} | Select-Object FullName"
  14.  
  15. pause
复制代码【方案2】以文件的最后创建时间为准 BAT + PowerShell
 
  1. @echo off
  2. REM ------------------------------------------------------------------------------
  3. REM 如果显示的待删除文件列表正确无误
  4. REM 把 Select-Object FullName 修改成 Remove-Item -Force 再次执行即可真正删除文件
  5. REM Win7/Win8/Win10等系统自带PowerShell
  6. REM ------------------------------------------------------------------------------
  7.  
  8. REM 指定待删除文件的存放路径
  9. set SrcDir=C:\Test\BatHome
  10. REM 指定天数
  11. set DaysAgo=10
  12.  
  13. powershell -c "Get-ChildItem -Path '%SrcDir%' -Recurse -ErrorAction:SilentlyContinue | Where-Object -FilterScript {(((get-date) - ($_.CreationTime)).days -gt %DaysAgo% -and $_.PsISContainer -ne $True)} | Select-Object FullName"
  14.  
  15. pause
复制代码【方案3】以文件的修改日期为准 forfiles
 
  1. @echo off
  2. REM ------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件。
  4. REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
  5. REM Win7/Win8/Win10等系统自带forfiles命令
  6. REM ------------------------------------------------------------------------------
  7.  
  8. REM 指定待删除文件的存放路径
  9. set SrcDir=C:\Test\BatHome
  10. REM 指定天数
  11. set DaysAgo=1
  12.  
  13. forfiles /p %SrcDir% /s /m *.* /d -%DaysAgo% /c "cmd /c echo del /f /q /a @path"
  14. pause
复制代码【方案4】以文件的最后修改时间为准 BAT + REG + VBS
 
  1. @echo off
  2. REM ------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件。
  4. REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
  5. REM 本例调用了临时VBS代码进行日期计算
  6. REM 本例为兼容不同的日期格式,调用reg命令(XP系统自带)统一设置日期格式,
  7. REM 处理完毕之后再把日期格式恢复成原来的状态。
  8. REM ------------------------------------------------------------------------------
  9.  
  10. REM 指定待删除文件的存放路径
  11. set SrcDir=C:\Test\BatHome
  12. REM 指定天数
  13. set DaysAgo=1
  14. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  15.     set "RegDateOld=%%a"
  16. )
  17. set RegDateOld=%RegDateOld:~-8%
  18. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  19. >"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
  20. >>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  21. >>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
  22. for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  23.     set "DstDate=%%a"
  24. )
  25. set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
  26. for /r "%SrcDir%" %%a in (*.*) do (
  27.     if "%%~ta" leq "%DstDate%" (
  28.         if exist "%%a" (
  29.             echo del /f /q "%%a"
  30.         )
  31.     )
  32. )
  33. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  34. pause
复制代码【方案5】以文件的最后修改时间为准 BAT + REG + Ritchie Lawrence 日期函数
 
  1. @echo off
  2. REM ------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件。
  4. REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
  5. REM 本例调用了 Ritchie Lawrence 的日期函数进行日期计算
  6. REM 日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
  7. REM 本例为兼容不同的日期格式,调用reg命令(XP系统自带)统一设置日期格式,
  8. REM 处理完毕之后再把日期格式恢复成原来的状态。
  9. REM ------------------------------------------------------------------------------
  10.  
  11. REM 指定待删除文件的存放路径
  12. set SrcDir=C:\Test\BatHome
  13. REM 指定天数
  14. set DaysAgo=1
  15. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  16.     set "RegDateOld=%%a"
  17. )
  18. set RegDateOld=%RegDateOld:~-8%
  19. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  20. call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
  21. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  22. set /a PassDays-=%DaysAgo%
  23. call :DaysToDate %PassDays% DstYear DstMonth DstDay
  24. set DstDate=%DstYear%-%DstMonth%-%DstDay%
  25. for /r "%SrcDir%" %%a in (*.*) do (
  26.     if "%%~ta" leq "%DstDate%" (
  27.         if exist "%%a" (
  28.             echo del /f /q "%%a"
  29.         )
  30.     )
  31. )
  32. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  33. pause
  34. goto :eof
  35.  
  36. :DateToDays %yy% %mm% %dd% days
  37. setlocal ENABLEEXTENSIONS
  38. set yy=%1&set mm=%2&set dd=%3
  39. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
  40. set /a dd=100%dd%%%100,mm=100%mm%%%100
  41. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
  42. set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
  43. endlocal&set %4=%j%&goto :EOF
  44.  
  45. :DaysToDate %days% yy mm dd
  46. setlocal ENABLEEXTENSIONS
  47. set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
  48. set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
  49. set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
  50. (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
  51. endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码【方案6】以文件的最后修改时间为准 BAT + VBS
 
  1. @echo off
  2. REM ------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件。
  4. REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
  5. REM 本例调用了临时VBS代码进行日期计算,并统一设置系统日期格式,处理完毕
  6. REM 之后再把日期格式恢复成原来的状态。摆脱了对reg命令(XP系统自带)的依赖。
  7. REM ------------------------------------------------------------------------------
  8.  
  9. REM 指定待删除文件的存放路径
  10. set SrcDir=C:\Test\BatHome
  11. REM 指定天数
  12. set DaysAgo=1
  13. >"%temp%\BackupDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
  14. >>"%temp%\BackupDate.vbs" echo WScript.Echo WshShell.RegRead ("HKEY_CURRENT_USER\Control Panel\International\sShortDate")
  15. for /f %%a in ('cscript /nologo "%temp%\BackupDate.vbs"') do (
  16.     set "RegDateOld=%%a"
  17. )
  18. >"%temp%\UnifyDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
  19. >>"%temp%\UnifyDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "yyyy-M-d", "REG_SZ"
  20. cscript /nologo "%temp%\UnifyDate.vbs"
  21. >"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
  22. >>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  23. >>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
  24. for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  25.     set "DstDate=%%a"
  26. )
  27. set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
  28. for /r "%SrcDir%" %%a in (*.*) do (
  29.     if "%%~ta" leq "%DstDate%" (
  30.         if exist "%%a" (
  31.             echo del /f /q "%%a"
  32.         )
  33.     )
  34. )
  35. >"%temp%\RecoverDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
  36. >>"%temp%\RecoverDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "%RegDateOld%", "REG_SZ"
  37. cscript /nologo "%temp%\RecoverDate.vbs"
  38. pause
复制代码【方案7】以文件的创建时间为准 BAT + REG + Ritchie Lawrence 日期函数
 
  1. @echo off
  2. REM ------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件的创建日期为准)的文件。
  4. REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
  5. REM 本例调用了 Ritchie Lawrence 的日期函数进行日期计算
  6. REM 日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
  7. REM 本例为兼容不同的日期格式,调用reg命令(XP系统自带)统一设置日期格式,
  8. REM 处理完毕之后再把日期格式恢复成原来的状态。
  9. REM ------------------------------------------------------------------------------
  10.  
  11. REM 指定待删除文件的存放路径
  12. set SrcDir=C:\Test\BatHome
  13. REM 指定天数
  14. set DaysAgo=1
  15. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  16.     set "RegDateOld=%%a"
  17. )
  18. set RegDateOld=%RegDateOld:~-8%
  19. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  20. call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
  21. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  22. set /a PassDays-=%DaysAgo%
  23. call :DaysToDate %PassDays% DstYear DstMonth DstDay
  24. set DstDate=%DstYear%-%DstMonth%-%DstDay%
  25.  
  26. for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (
  27.     call :CompareTime "%%a"
  28. )
  29. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  30. pause
  31. goto :eof
  32.  
  33. :DateToDays %yy% %mm% %dd% days
  34. setlocal ENABLEEXTENSIONS
  35. set yy=%1&set mm=%2&set dd=%3
  36. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
  37. set /a dd=100%dd%%%100,mm=100%mm%%%100
  38. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
  39. set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
  40. endlocal&set %4=%j%&goto :EOF
  41.  
  42. :DaysToDate %days% yy mm dd
  43. setlocal ENABLEEXTENSIONS
  44. set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
  45. set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
  46. set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
  47. (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
  48. endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
  49.  
  50. :CompareTime
  51. for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (
  52.     if "%%h" leq "%DstDate%" (
  53.         if exist %1 (
  54.             echo del /a /f /q %1
  55.         )
  56.     )
  57.     goto :eof
  58. )
复制代码【方案8】以文件名中包含的日期字符串为准 字符串截取
 
  1. @echo off
  2. REM ------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件名中包含的日期字符串为准)的文件。
  4. REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
  5. REM 本例假设文件名中包含的日期字符串(比如:bak-2009-12-25.log)
  6. REM ------------------------------------------------------------------------------
  7.  
  8. REM 指定待删除文件的存放路径
  9. set SrcDir=C:\Test\BatHome
  10. REM 指定天数
  11. set DaysAgo=1
  12.  
  13. >"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
  14. >>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  15. >>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
  16. for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  17.   set "DstDate=%%a"
  18. )
  19. set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
  20.  
  21. setlocal enabledelayedexpansion
  22. for /r "%SrcDir%" %%a in (*.*) do (
  23.     set "FileDate=%%~na"
  24.     set "FileDate=!FileDate:~4,10!"
  25.     if "!FileDate!" leq "%DstDate%" (
  26.         if exist "%%a" (
  27.             echo del /f /q "%%a"
  28.         )
  29.     )
  30. )
  31. endlocal
  32. pause
评论
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值