【NOIP2014八校联考第2场第2试】帮助Bsny

题目

Description

Bsny的书架乱成一团了，帮他一下吧！
他的书架上一共有n本书，我们定义混乱值是连续相同高度书本的段数。例如，如果书的高度是30，30，31，31，32，那么混乱值为3；30，32，32，31的混乱值也为3。但是31，32，31，32，31的混乱值为5，这实在是太乱了。
Bsny想尽可能减少混乱值，但他有点累了，所以他决定最多取出k本书，再随意将它们放回到书架上。你能帮助他吗？

Input

第一行两个整数n，k，分别表示书的数目和可以取出的书本数目。
接下来一行n个整数表示每本书的高度。

Output

仅一行一个整数，表示能够得到的最小混乱值。

Sample Input

5 1
25 26 25 26 25

Sample Output

3

Data Constraint

20%的数据：1≤n≤20，k=1。
40%的数据：书的高度不是25就是32，高度种类最多2种。
100%的数据：1≤k≤n≤100，注意所有书本高度在[25,32]。

题解

显然是dp，设f[i,j,k,l]表示我当前在处理第i个数，前面已经用了K次拿出，现在前面的状态为k（k是一个二进制，表示没一种书有没有），l则表示前面的一个数是什么
然后就是考虑当前这一位是否拿出来了
如果不拿出来，转移十分显然，只要考虑一下a[i]和l是否相等就可以了
如果拿出来可以往前放，也可以往后放，好像很难处理耶（特别是往后放）
往前放的话肯定是尽量放到“自己人”旁边，那样对答案就没有贡献了嘛，但是如果没有就没有办法，只能+1了
那如果往后放呢？怎么处理放到哪里？会不会因为又要移多一次产生影响？
事实上并不用确定要移到哪里，只要确定后面有没有“自己人”就可以了
为什么呢？
因为不管后面那个“自己人”移到哪里，我们这一块就跟着他移到那里就好了，并不需要分多次移动
那么转移就很显然了

贴代码

var
    a,c,g:array[0..105]of longint;
    f:array[0..105,0..105,0..256,0..9]of longint;
    cc:array[0..10]of longint;
    yu1:array[0..305]of longint;
    i,j,k,l,n,m,x,y,z,ans:longint;
function min(x,y:longint):longint;
begin
    if x<y then exit(x) else exit(y);
end;
begin
    //assign(input,'t2.in'); reset(input);
    readln(n,k);
    y:=1;
    for i:=1 to n do
    begin
        read(x);
        if x-24=a[m] then inc(y) else
        begin
            c[m]:=y;
            y:=1;
            inc(m);
            a[m]:=x-24;
        end;
    end;
    c[m]:=y;
    readln;
    n:=m;
    cc[1]:=1;
    for i:=2 to 10 do cc[i]:=cc[i-1]*2;
    for i:=n downto 1 do yu1[i]:=yu1[i+1] or cc[a[i]];
    fillchar(f,sizeof(f),$7f div 3);
    f[0,0,0,0]:=0;
    for i:=1 to n do
    begin
        for j:=0 to k do
            for x:=0 to cc[9]-1 do
                for y:=0 to 8 do
                if f[i-1,j,x,y]<=100 then
                begin
                    if y<>a[i] then
                    f[i,j,x or cc[a[i]],a[i]]:=min(f[i,j,x or cc[a[i]],a[i]],f[i-1,j,x,y]+1)
                    else
                    f[i,j,x or cc[a[i]],a[i]]:=min(f[i,j,x or cc[a[i]],a[i]],f[i-1,j,x,y]);
                    if j+c[i]<=k then
                    begin
                        z:=j+c[i];
                        f[i,z,x or cc[a[i]],y]:=min(f[i,z,x or cc[a[i]],y],f[i-1,j,x,y]+1);
                        if x and cc[a[i]]>0 then
                        begin
                            f[i,z,x,y]:=min(f[i,z,x,y],f[i-1,j,x,y]);
                        end else
                        if yu1[i+1] and cc[a[i]]>0 then
                        begin
                            f[i,z,x,y]:=min(f[i,z,x,y],f[i-1,j,x,y]);
                        end;
                    end;
                end;
    end;
    ans:=n;
    for j:=0 to k do
        for x:=0 to cc[9]-1 do
            for y:=0 to 8 do
            begin
                ans:=min(ans,f[n,j,x,y]);
            end;
    writeln(ans);
    //close(input);
end.