【SSLGZ 1579】泽泽在巴西

问题描述
泽泽帮助了英国某街道尽量减少酸雨的伤害，街道办主任非常感激他，就把他领到一扇门前，告诉他这扇门能通往好地方，具体好到什么程度要看泽泽人品。泽泽毫不犹豫地走了进去……
　　泽泽来到了足球王国——巴西。这可是个好地方，泽泽看来人品攒了不少了。这里大街小巷都在踢足球，其乐无穷。
突然，泽泽被一个人拎了起来，一看，是个足球流氓。他后面跟了一大群足球流氓，正虎视眈眈地看他。他们要求和泽泽比赛，输了就要揍他。
　　没办法，泽泽硬着头皮和足球流氓另外掳来的几个人一起组建了一只队伍，和足球流氓队比赛。
　　比赛开始，泽泽队率先发球。泽泽观察了四周，想怎么才能用最短的时间射门呢？
　　射门的时间为距离*2，而传球的时间是距离*1。所以泽泽想找一条用时最少的射门路径，来打败足球流氓。
　　足球流氓当然不会袖手旁观，他们会拦截。当泽泽队伍中的传球人、被传球人之间有某足球流氓并且他们在同一直线上时，传球不会成功，即不能这样传球。比如A（1，2）想传球给B（7，8），中间有个足球流氓C（3，4），则他们在同一直线，传球不成功。射门不受足球流氓影响。
输入
第1行3个整数x0，y0，n，m。x0，y0表示球门的坐标，n表示泽泽队伍有几个人，m表示足球流氓有几个人。
接下来的n行，分别有2个整数，表示泽泽球队的球员坐标。其中最前面的2个整数是泽泽的坐标。球一开始在泽泽脚下。
接下来的m行，分别有2个整数，表示足球流氓的球员坐标。
保证不会有2个人坐标相同。
样例输入
0 0 5 2
20 20
27 -14
0 16
-7 -9
23 38
22 24
3 0
样例输出
52
算法讨论
先读入每个点的坐标信息，利用叉积判断每两个球员之间或与球门之间是否有流氓，有的话就删除这一边，没有的话就加入到数组中，注意双向，构完图后跑一遍最短路就OK了。

const
  maxn=3000;
  maxm=300000;
var
  a,b:array[1..maxn,1..3] of longint;
  x,y,ls,next,list,v:array[1..maxm] of longint;
  w,d:array[1..maxm] of real;
  i,j,n,m,xx,yy,p:longint;

function check(x1,y1,x2,y2,x,y:longint):boolean;
begin
  if (x>x1) and (x>x2) or (y>y1) and (y>y2) or (x<x1) and (x<x2) or (y<y1) and (y<y2)
    then exit(false)
    else exit(true)
end;

function cp(x1,y1,x2,y2,x,y:longint):longint;
var
  ans:longint;
begin
  ans:=(x1-x)*(y2-y)-(x2-x)*(y1-y);
  exit(ans)
end;

procedure del;
var
  i,j,k:longint;
  flag:boolean;
begin
  for i:=1 to n do
    for j:=i+1 to n+1 do
      begin
        flag:=true;
        for k:=1 to m do
          if (cp(a[j,1],a[j,2],b[k,1],b[k,2],a[i,1],a[i,2])=0) and (check(a[i,1],a[i,2],a[j,1],a[j,2],b[k,1],b[k,2]))
            then begin
                   flag:=false;
                   break
                 end
            else continue;
        if flag
          then begin
                 inc(p);
                 x[p]:=a[i,3];
                 y[p]:=a[j,3];
                 if j<>n+1
                   then w[p]:=sqrt(sqr(a[i,1]-a[j,1])+sqr(a[i,2]-a[j,2]))
                   else w[p]:=2*sqrt(sqr(a[i,1]-a[j,1])+sqr(a[i,2]-a[j,2]));
                 next[p]:=ls[x[p]];
                 ls[x[p]]:=p;
                 inc(p);
                 x[p]:=y[p-1];
                 y[p]:=x[p-1];
                 w[p]:=w[p-1];
                 next[p]:=ls[x[p]];
                 ls[x[p]]:=p
               end;
      end;
end;

procedure spfa;
var
  hd,tl,t:longint;
begin
  hd:=0; tl:=1;
  list[1]:=1;
  v[1]:=1;
  while hd<>tl do
    begin
      inc(hd);
      t:=ls[list[hd]];
      while t>0 do
        begin
          if d[x[t]]+w[t]<d[y[t]]
            then begin
                   d[y[t]]:=d[x[t]]+w[t];
                   if v[y[t]]=0
                     then begin
                            v[y[t]]:=1;
                            inc(tl);
                            list[tl]:=y[t]
                          end;
                 end;
          t:=next[t]
        end;
      v[list[hd]]:=0
    end;
end;

begin
  readln(xx,yy,n,m);
  for i:=1 to n do
    begin
      read(a[i,1],a[i,2]);
      a[i,3]:=i
    end;
  a[i+1,1]:=xx; a[i+1,2]:=yy;
  a[i+1,3]:=i+1;
  for i:=1 to m do
    read(b[i,1],b[i,2]);
  del;
  for i:=1 to n+1 do
    d[i]:=maxlongint;
  d[1]:=0;
  spfa;
  write(d[n+1]:0:0)
end.

Pixiv ID：61828880