最小背包

最小背包
（源程序名：beibao.pas，可执行文件名：beibao.exe）
（输入文件名：beibao.in，输出文件名：beibao.out）
有一个游乐场里共有n个玩具，每个玩具的体积为v[i],重量为w[i]。小源同学在这个游乐场中了"免费选择玩具"大奖。他可以选择部分的玩具直接带回家，不过他只有一个容量为x的背包，所以他要想办法选出喜欢的玩具来装满背包，并且游乐场有规定，如果你选的玩具不能正好装满背包就不能带走。由于小源同学只有6岁，力气很小，所以他希望装满背包的同时，里面玩具的重量能够最小，请你帮忙解决下这个问题。
输入：
 第一行为两个整数n,x，表示有n个玩具，背包容量为x.
 后面n行每行两个整数v[i],w[i] 表示第i个物品的体积和重量。
输出:
 最小的重量.
 如果无法装满背包输出'impossible'
样例输入 Sample Input
 例（一）
5 20
10 30
10 20
5  10
5  15
8  10
例（二）
5 20
10 10
6  10
7  10
8  10
11 10
样例输出 Sample Output
 例（一）
45
例（二）
impossible


（例一说明）
装满背包的方案有三种，分别为50 45 55，所以最小为45
 
各个测试点1s
30%的数据n<=30
70%的数据n<=100
100%的数据n<=3000

对于100%的数据x<=10000  v[i],w[i]<=2000

该题 回溯不优化 50
优化 70
二维背包 70
一维背包 满分
那么让我们来思考一下这道题，它要求出装满背包的最小重量，注意，是恰好装满！那么，平时的01背包照搬是不可能的，因为许多01背包并没有要求恰好装满。
那么怎么才能求出恰好装满的方案呢？我们需要依靠初始化来解决这个问题
例如有3个物品，背包容量为10
物品的体积与重量 
5 10
5 5
10 5
我们需要把f[0]设为0，1 to 背包容量都设为一个很大的数（远远大于体积和重量的）假设这个很大的数是maxlongint吧，当然会有超出longint的错误，但是可以帮助我们理解：
for i:=1 to n do 
for x:=背包容量 downto a[i] do 
f[x]:=min(f[x],f[x-a[i]]+b[i]);
让我们模拟一下，当运算第一个物品时
f[10]:=min(f[10],f[10-5]+10)=min(maxlongint,maxlongint+10)=maxlongint;
看到了吗？f[10]依然是maxlongint，因为它不是一个合法的位置，同理，除了f[5]外，f[1]到f[10]都还是maxlongint,那为什么f[5]不是maxlongint呢？因为f[5]:=min(f[5],f[5-5]+10)=(maxlongint,10)=10;
因为f[0]:=0所以f[5]就是10了，它是一个合法的位置，可以恰好装满。以此类推，每个物品都会产生相应的合法位置，最后的答案即为f[m]

var f:array[0..10000]of qword;
a,b:array[1..3000]of longint;
n,m,i,x:longint;
function min(a,b:qword):qword;
begin
  if a<b then exit(a) else exit(b);
end;
begin
  readln(n,m);
  for i:=1 to n do readln(a[i],b[i]);
  f[0]:=0;
  for i:=1 to m do f[i]:=maxlongint;
  for i:=1 to n do
  for x:=m downto a[i] do
  f[x]:=min(f[x],f[x-a[i]]+b[i]);
  if f[m]=maxlongint then write('impossible') else write(f[m]);
end.