CO11N报工使用BAPI_PRODORDCONF_CREATE_TT时无法返回配置错误消息CK466

文章描述了在使用CO11N前台报工时遇到的一个问题,即特定配置错误(CK466)不会在调用BAPI_PRODORDCONF_CREATE_TT时返回。作者通过代码追踪发现错误只在特定情况下被捕获。为了解决这个问题,提出了一个重写系统预留增强选项的解决方案,通过调用CM_F_MESSAGES_GET函数并触发异常来确保错误消息能被BAPI返回。测试表明这种方法有效。

摘要生成于 C知道 ,由 DeepSeek-R1 满血版支持, 前往体验 >

前些天碰到一个问题,CO11N前台报工时,会触发一个配置E类型的消息CK466,但是在调用BAPI_PRODORDCONF_CREATE_TT时,该消息并不会返回,而是返回S类型消息。

错误重现:

1.kp26取消维护变动价格

2.SM30及SE16N将对应的错误消息类型更改为E

 视图:V_TCMF9

 表:TCMFA

 此时前台执行CO11N就会触发CK466的报错,经过代码追踪,发现问题所在:

Form det_conf_cost中,其实会捕获到配置的E类型消息,但是只会当以下三种情况时才会捕获错误消息且终止报工。

1.前台处理时:

2.后台处理时:

 3.当订单类型是网络订单时:

除此以外的情况,都不会打上取消标记并下入下面的错误处理逻辑:

所以问题就在于让BAPI调用时也能够将错误消息收集起来,经过对源码进一步分析,错误最终会返回在内表 t_cost_cmfnr 中,只需要找到合适的增强点,调用上述处理函数CM_F_MESSAGES_GET并触发异常no_costing,即可将配置出来的错误消息返回给BAPI的return参数。

解决方案:重写系统预留增强选项。

ENHANCEMENT 1  ZE_PRODCONF_CATCH_ERR.    "active version
* >>> Operation Account Assignment
* In the case of OLC PM/CS order need to initialize and then free
* a buffer for the order operations in the pmco_op update.
* This is due to performance issues when confirming mass operations
* especially during CAT9 transfer.
    IF cl_erp_co_olc_tools=>is_olc_relevant( caufvd-netzkont ) = abap_true AND
       caufvd-autyp = auftragstyp-inst.

      CALL FUNCTION 'PMCO_OPS_BUFFER_INIT'.
      PERFORM det_conf_cost USING caufvd.
      CALL FUNCTION 'PMCO_OPS_BUFFER_FREE'.

    ELSE.
      PERFORM det_conf_cost USING caufvd.
    ENDIF.

*   Catch cost error for BAPI BAPI_PRODORDCONF_CREATE_TT
    IF flg_bapi = abap_true.
      READ TABLE t_cost_cmfnr INTO DATA(ls_cost_cmfnr)
        WITH KEY msgty = 'E'.
      IF sy-subrc = 0.
        ROLLBACK WORK.

        DATA lt_cmfmsg TYPE STANDARD TABLE OF cmfmsg.

        MOVE-CORRESPONDING t_cost_cmfnr[] TO lt_cmfmsg.

*       Bei Storno Fehlermeldung aus CO anzeigen
        CALL FUNCTION 'CM_F_MESSAGES_GET'
           EXPORTING
             aplid                  = aplid_ppru
           TABLES
             e_msgprot              = lt_cmfmsg
           EXCEPTIONS
             not_active             = 1
             OTHERS                 = 2.

        IF sy-subrc IS INITIAL.
*         Erste Fehlermeldung ausgeben
          READ TABLE lt_cmfmsg INTO DATA(ls_cmfmsg)
                               WITH KEY msgty = message_type-error.
          MESSAGE ID ls_cmfmsg-arbgb TYPE message_type-error
                  NUMBER ls_cmfmsg-msgnr WITH ls_cmfmsg-msgv1
                  ls_cmfmsg-msgv2 ls_cmfmsg-msgv3 ls_cmfmsg-msgv4
                  RAISING no_costing.
        ENDIF.

        IF caufvd-autyp NE auftragstyp-netw.
          MESSAGE a085 WITH caufvd-aufnr RAISING no_costing.
        ELSE.
          MESSAGE a087 WITH caufvd-aufnr RAISING no_costing.
        ENDIF.
      ENDIF.
    ENDIF.
* <<< Operation Account Assignment
ENDENHANCEMENT.

 代码测试:

REPORT ztest_13065_co11n.

DATA:
  ls_propose            TYPE bapi_pp_conf_prop,
  lt_timetickets        TYPE STANDARD TABLE OF bapi_pp_timeticket,
  ls_timetickets        TYPE bapi_pp_timeticket,
  lt_goodsmovements     TYPE STANDARD TABLE OF bapi2017_gm_item_create,
  ls_goodsmovements     TYPE bapi2017_gm_item_create,
  lt_link_conf_goodsmov TYPE STANDARD TABLE OF bapi_link_conf_goodsmov,
  lt_return             TYPE STANDARD TABLE OF bapi_coru_return,
  ls_return             TYPE bapiret1.

ls_propose-quantity      = 'X'.
ls_propose-activity      = 'X'.
ls_propose-date_and_time = 'X'.
ls_propose-goodsmovement = 'X'.

ls_timetickets-orderid   = '000001001322'.
ls_timetickets-operation = '0010'.
APPEND ls_timetickets TO lt_timetickets.

ls_goodsmovements-orderid    = '000001001322'.
ls_goodsmovements-order_itno = '0010'.
APPEND ls_goodsmovements TO lt_goodsmovements.


CALL FUNCTION 'BAPI_PRODORDCONF_GET_TT_PROP'
  EXPORTING
    propose            = ls_propose
  IMPORTING
    return             = ls_return
  TABLES
    timetickets        = lt_timetickets
    goodsmovements     = lt_goodsmovements
    link_conf_goodsmov = lt_link_conf_goodsmov
*   DETAIL_RETURN      =
*   FSH_BUNDLES        =
  .

CALL FUNCTION 'BAPI_PRODORDCONF_CREATE_TT'
  EXPORTING
    post_wrong_entries    = '2'
*   testrun               = 'X'
*    call_on_inbound_queue = 'A'
  IMPORTING
    return                = ls_return
  TABLES
    timetickets           = lt_timetickets
    goodsmovements        = lt_goodsmovements
    link_conf_goodsmov    = lt_link_conf_goodsmov
*   CHARACTERISTICS_WIPBATCH       =
*   LINK_CONF_CHAR_WIPBATCH        =
    detail_return         = lt_return
*   CHARACTERISTICS_BATCH =
*   LINK_GM_CHAR_BATCH    =
  .

cl_demo_output=>new( )->begin_section( 'ls_return' )->write_data( ls_return
                     )->begin_section( 'lt_return' )->write_data( lt_return
                     )->display( ).

BAPI返回结果:

同理应该可以解决类似情况的相同问题,以上。

评论
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

DeveloperMrMeng

觉得有用的佛系投币哦

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付:¥1
获取中
扫码支付

您的余额不足,请更换扫码支付或充值

打赏作者

实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值