Windows下载安装zookeeper

目的：Windows下载安装zookeeper

环境：

系统：Win10
环境：

---

一、下载zookeeper。

下载链接：https://mirrors.tuna.tsinghua.edu.cn/apache/zookeeper/zookeeper-3.4.14/, 找到对应版本(这里以5.7为例)，。如下图：

二、 Windows版本zookeeper安装

1.将zookeeper解压到指定文件夹(以本机为例)，并在根目录下新建两个文件夹：名为data和logs，如下图

2.然后复制根目录下conf目录中的zoo_sample.cfg，改名为zoo.cfg, 并修改zoo.cfg文件配置， 如下图

3.控制台窗口cd进入跟目下的bin目录，执行zkServer.cmd启动zookeeper，如下图

4.将zookeeper加入系统服务。(参考链接： https://blog.youkuaiyun.com/xht555/article/details/81571389)

a. 下载Apache出品的通用后台进程服务插件包：commons-daemon，下载地址：http://archive.apache.org/dist/commons/daemon/binaries/windows/ ，目前最新版本是1.1.0,如下图

b. 解压下载的安装包，将其中的prunmgr.exe和prunsrv.exe复制到zookeeper根目录下的bin目录中(若主机是64位，则拷贝amd64文件夹中的prunsrv.exe), 如下图：


c. 在zookeeper根目录下新建zk-server-install.bat(加入系统服务), zk-server-remove.bat(移除系统服务), zk-stop.bat(停止服务)三个文件，并编辑内容(特别注意编辑bat文件的编码为ANSI编码), 如下图：




d. 右键zk-server-install.bat并以管理员权限执行，然后进入系统服务，设置zookeeper服务, 如下图：

附代码：

REM # zk-server-install.bat

@echo off
 
REM #
REM # 说明：在Windows系统中安装ZooKeeper服务，实现以服务的方式启动ZooKeeper
REM # 注意：此脚本必须拷贝到ZooKeeper的根目录，否则运行报错
REM # ZK_HOME：			ZooKeeper安装目录
REM # ZK_DATA_DIR：		ZooKeeper数据目录
REM # ZK_SERVICE_NAME:	ZooKeeper服务名
REM #
REM # 服务启动命令：net start ZooKeeper
REM # 服务停止命令：net stop ZooKeeper
 
CD /d %~dp0
SET ZK_HOME=%CD%
SET ZK_DATA_DIR=%ZK_HOME%\data
SET ZK_LOG_DIR=%ZK_HOME%\log
SET ZK_SERVICE_NAME=ZooKeeper
if not exist %ZK_DATA_DIR% mkdir %ZK_DATA_DIR%
if not exist %ZK_LOG_DIR% mkdir %ZK_LOG_DIR%
 
:: 安装ZooKeeper的Windows服务
%ZK_HOME%\bin\prunsrv.exe "//IS//%ZK_SERVICE_NAME%" ^
--DisplayName="%ZK_SERVICE_NAME%" ^
--Description="%ZK_SERVICE_NAME%" ^
--Startup=auto ^
--StartMode=exe ^
--StartPath=%ZK_HOME% ^
--StartImage=%ZK_HOME%\bin\zkServer.cmd ^
--StopPath=%ZK_HOME%\ ^
--StopImage=%ZK_HOME%\zk-stop.bat ^
--StopMode=exe ^
--StopTimeout=5 ^
--LogPath=%ZK_LOG_DIR% ^
--LogPrefix=zookeeper-wrapper ^
--PidFile=zookeeper.pid ^
--LogLevel=Info ^
--StdOutput=auto ^
--StdError=auto
 
pause

REM # zk-server-remove.bat

@echo off
 
REM #
REM # 说明：卸载ZooKeeper的Windows服务
REM # 注意：此脚本必须拷贝到ZooKeeper的根目录，否则运行报错
REM #
 
CD /d %~dp0
%CD%\bin\prunsrv.exe //DS//ZooKeeper

zk-stop.bat

@echo off
 
REM #
REM # 说明：以杀进程的方式停止ZooKeeper服务
REM # 注意：此脚本必须拷贝到ZooKeeper的根目录，否则运行报错
REM #
 
setlocal
 
CD /d %~dp0
 
:: 以杀进程的方式停止ZooKeeper服务
SET /p zkPID=<%CD%\log\zookeeper.pid
taskkill /PID %zkPID% /T /F
 
endlocal

附带zookeepeer3.4.14
https://download.youkuaiyun.com/download/alger_magic/11180698